// Importing High Speed Hyperspectral Raman Timeseries data into hyperstacks

// 		1) Get image directories list (locate, list folders, import CARS&SRS,
// 			rename appropriately)
//		2) Make blank hyperstack
// 		3) Import each timeseries into respective hyperstacks (CARS & SRS)

// Locate image directories
dirpar = getDirectory("Choose a Directory"); // parent folder directory
print("START LOADING:: "+dirpar)
dirlist = getFileList(dirpar)
filename = File.getName(dirpar)
//Array.print(dirlist)

print("list length = "+dirlist.length)
length = dirlist.length;
firstimg = "ChanA_0001_0001_0001_0001.tif"
print("List[0] = "+dirlist[0])
firststack = dirpar+dirlist[0]+firstimg

run("Bio-Formats Importer", "open=[&firststack] color_mode=Default rois_import=[ROI manager] split_channels view=[Standard ImageJ] stack_order=Default");
selectWindow("ChanA_0001_0001_0001_0001.tif - C=0")
rename(filename+"_CARS")
CARSstack = getTitle()
selectWindow("ChanA_0001_0001_0001_0001.tif - C=1")
rename(filename+"_SRS")
SRSstack = getTitle()

for (i = 1; i<dirlist.length; i++){
	nextstack = dirpar+dirlist[i]+firstimg;
	print("Loading "+nextstack);
	run("Bio-Formats Importer", "open=[&nextstack] color_mode=Default rois_import=[ROI manager] split_channels view=[Standard ImageJ] stack_order=Default");
	run("Concatenate...", "  title=[&CARSstack] open image1=[&CARSstack] image2=[ChanA_0001_0001_0001_0001.tif - C=0] image3=[-- None --]");
	run("Concatenate...", "  title=[&SRSstack] open image1=[&SRSstack] image2=[ChanA_0001_0001_0001_0001.tif - C=1] image3=[-- None --]");
	print("Loaded " + toString(i) + " - " + dirlist[i]);
};

print("Stack Loading Complete");
selectWindow(CARSstack);
run("Stack to Hyperstack...", "order=xytcz channels=&length slices=1 frames=250 display=Grayscale");
selectWindow(SRSstack);
run("Stack to Hyperstack...", "order=xytcz channels=&length slices=1 frames=250 display=Grayscale");
print("Stack Reordering Complete");



//run("Bio-Formats Importer", "open=[Z:/Wilson/2019_02_16 INS Beads and Cells Finally/HSCellINS_003/HSCellINS_/ChanA_0001_0001_0001_0001.tif] color_mode=Default rois_import=[ROI manager] split_channels view=[Standard ImageJ] stack_order=Default");