//Define Input Dialog///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
requires("1.45f");
Dialog.create("MoloCutter Setup");
	Dialog.addMessage("MoloCutter Requires ImageJ v.1.45f") 
	Dialog.addMessage("Enter Values for Image Adjustment") 
	Dialog.addSlider("Brightness Min:", 0, 65000, 100);
	Dialog.addSlider("Brightness Max:", 0, 65000, 5000);
	Dialog.addChoice("LUT for Straylight images", newArray("Fire", "Grays", "Ice", "Spectrum"), "Fire") //define colorcode of straylight images
	//Dialog.addCheckbox("Delete Original files2", false); //if checked "tif" images are deleted further down in the code
	Dialog.addCheckbox("Generate single JPG Image", false); //if checked "tif" images of every flow chamber are exported	
Dialog.show();

//Save variables of Dialog///////////////////////// transfered in order of apperance in the dialoge
	Min = Dialog.getNumber();
	Max = Dialog.getNumber();
	LUT = Dialog.getChoice();							
	//Delete = Dialog.getCheckbox();
	Single_export = Dialog.getCheckbox();							
		//print("Values:", Min);
		//print("Values:", Max);
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Get Directory //////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
path = File.openDialog("Select a File");
  	print("Path:", path);
dir = File.getParent(path);
	print("Directory:", dir);
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Defining Function for processing image /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
function process(filename) {
	open(filename);       	
	makeRectangle(10, 248, 441, 327);		//Define Crop area
	run("Crop");						//Crop images to Molo area
	setMinAndMax(Min, Max);				//Set Brightness
	run(LUT);						//Apply coloring to images
		wait(100);					//If no wait the LUT is not applied properly

	//Filename extrahieren/////////////////////////////////
		Filename=getTitle();
			print("Filename:", Filename);
		Filename_end = indexOf(Filename, ".tif"); 		//Weleche Position hat ".tif"
		Filename= substring (Filename, 0, Filename_end); 	//Titel extrahieren von Position "0" bis ".tif"
			print("Filename:", Filename);
			////////////////////////////////////////////////////
			//Position extrahieren//////////////////////////////
			Position_end = indexOf(Filename, "_"); 				
			Position = substring (Filename, 0, Position_end); 	
			print("Position:", Position); 
			////////////////////////////////////////////////////

			////////////////////////////////////////////////////
			/*Instrument///////////////////////////////////////
			Looks in the Filename for the Instrument Type
			*/
			Instrument_start = indexOf(Filename, "_Z");
			Instrument_start = Instrument_start + 1;	//increase start index to get rid of text in front of value
			Instrument_end = Instrument_start + 2;
			Instrument = substring (Filename, Instrument_start, Instrument_end); 	//Titel extrahieren von Position "0" bis ".tif"
				print("Instrument:", Instrument);
			////////////////////////////////////////////////////


	//MetaInfo extrahieren/////////////////////////////////
		MetaInfo = getMetadata("Info");			//MetaInfos auslesen
			print("MetaInfo:", MetaInfo);	
			////////////////////////////////////////////////////
			/*Emission filter///////////////////////////////////
			Looks in the MetaInfos for the type of Emmsion filter and colors the image accordingly
			Looks for [title="Emission filter" value="Red"] if not present value=-1
			*/
			Emission = indexOf(MetaInfo, "title=\"Emission filter\" value=\"Red\""); 	//wenn der String gefundenwird wird LUT "Red" verwendet	
				print("Emission:", Emission);
				if (Emission!=-1) 
				{
				 run("Red");
				 wait(100);		//If no wait the LUT is not applied properly
 				} 
 			Emission = indexOf(MetaInfo, "title=\"Emission filter\" value=\"Green\""); 	//wenn der String gefundenwird wird LUT "Gr�n" verwendet
				//print("MetaTitel:", Emission);						//if both is not found it stays as it is
				if (Emission!=-1) 
				{
				 run("Green");
				 wait(100);		//If no wait the LUT is not applied properly
 				} 
			////////////////////////////////////////////////////

			////////////////////////////////////////////////////
			/*Coupling value///////////////////////////////////
			Looks in the MetaInfos for the coupling value
			Looks for [title="Coupling value" value="] if not present value=-1
			*/
			Coupling_start = indexOf(MetaInfo, "title=\"Coupling value\" value=");
			Coupling_start = Coupling_start + 30;	//increase start index to get rid of text in front of value
				print("C_start:", Coupling_start);
			Coupling_end = indexOf(MetaInfo, "\"/><CouplingGrayFilter");
				print("C_end:", Coupling_end);
			Coupling = substring (MetaInfo, Coupling_start, Coupling_end); 	//Titel extrahieren von Position "0" bis ".tif"
				print("Coupling value:", Coupling);
			////////////////////////////////////////////////////
	//Draw Infos into image///////////////////////////////////
		setFont("Sanserif", 20);
		setColor("black");

  		drawString(Position, 10, 40, "white");
  		drawString("Coupling:" + Coupling, 50, 40, "white");
  		drawString("Min-Max:" + Min + "-" + Max, 230, 40, "white");
  		drawString(Instrument, 10, 80, "white");
  		wait(100);											//waiting for drawing
		

	//Draw Infos into image///////////////////////////////////
		run("RGB Color");  	//Convert in RGB for colored stack

	//Speichern als JPG/////////////////////////////////
		if (Single_export==true)	
		saveAs("Jpeg", dir + "/" + Filename);						//Speichern als JPG
}
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Read directory and open files sequencially /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

filelist = getFileList(dir);
	Array.sort(filelist );				//sorts images in array 
	for (i = 0; i < filelist.length; i++)
	{ 
	if(endsWith(filelist[i],".tif")) 			//opens only ".tiff" images
							//more constrains: if(endsWith(list[i],".tif")&&indexOf(list[i],"foes")=1)
		{ 
        		process(filelist[i]); 
		//print (filelist[i]);
        		} 
	}
	
	//open(filelist[i]);
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////



//Generation of Montage///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////// 

	//Number of open Iimages for cal�culation of the montage////////////////////////////////////////////////////////////////////////////////////////////// 
		openImages = nImages();									//Get number of all open Images
 			print(openImages); 
	//////////////////////////////////////////////////////////////////////////////////////////////////

	//Generate Stack of montage////////////////////////////////////////////////
		run("Images to Stack", "name=Stack title=[] use ");
		//MetaInfo for generation of new Filename/////////////////////////////////
			MetaInfo_Stack = getMetadata("Info");						//MetaInfos auslesen
				print("MetaInfo:", MetaInfo_Stack);	
			Montage_start = indexOf(MetaInfo_Stack, "[");
			Montage_end = indexOf(MetaInfo_Stack, ".tif");		
			MontageTitel = substring (MetaInfo_Stack, Montage_start, Montage_end); 	//Titel extrahieren von Position "[" bis ".tif"
				print("MontageTitel:", MontageTitel);
		////////////////////////////////////////////////////////////////////////////////////////////////////////

	//Generate Montage////////////////////////////////////////////////
		columns = openImages / 3;
		columns = -floor(-columns);  								//floor(x) rounds down, while -floor(-x) rounds up.
		run("Make Montage...", "columns=3 rows="+columns+" scale=1.0");
		saveAs("Jpeg", dir + "/BarScan_" + MontageTitel);					//Speichern als JPG
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Cleaning up///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
close();		//close Montage		
close();		//close Stack

//Closing Log Window/////////////////////////////
if (isOpen("Log")) { 
    selectWindow("Log"); 
    run("Close"); 
    }