//Define Input Dialog///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
requires("1.45f");
Dialog.create("MoloCutter Setup");
	Dialog.addMessage("MoloCutter Requires ImageJ v.1.45f") 
	Dialog.addMessage("Enter Values for Image Adjustment") 
	Dialog.addSlider("Brightness Min:", 0, 65000, 100);
	Dialog.addSlider("Brightness Max:", 0, 65000, 5000);
	Dialog.addChoice("LUT for Straylight images", newArray("Fire", "Grays", "Ice", "Spectrum"), "Fire") //define colorcode of straylight images
	Dialog.addCheckbox("Delete Original files", false); //if checked "tif" images are deleted further down in the code
Dialog.show();
///////////////////////////////////////////////////////	
	//Save variables of Dialog///////////////////////// transfered in order of apperance in the dialoge
	Min = Dialog.getNumber();
	Max = Dialog.getNumber();
	LUT = Dialog.getChoice();							
	Delete = Dialog.getCheckbox();						
		//print("Values:", Min);
		//print("Values:", Max);
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Get Directory ////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
path = File.openDialog("Select a File");
  	//print("Path:", path);
dir = File.getParent(path);
	//print("Directory:", dir);
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Open and process images //////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
run("Image Sequence...", "open="+path+" sort");			//Image Sequence of all Images
	makeRectangle(10, 248, 441, 327);					//Define Crop area
	run("Crop");										//Crop images to Molo area
	setMinAndMax(Min, Max);								//Set Brightness
	run(LUT);											//Apply coloring to images
	wait(100);											//If no wait the LUT is not applied properly

run("Stack to Images");									//Separete Images for unique processing
	openImages = nImages();								//Get number of all open Images
 		//print(openImages); 

i = 0;													//Loop index
while (i<openImages) 									//Start Loop for all open images
{
	//Titel extrahieren/////////////////////////////////
	MetaInfo = getMetadata("Info");						//MetaInfos auslesen
			//print("MetaInfo:", MetaInfo);		
	Titel_end = indexOf(MetaInfo, ".tif"); 				//Weleche Position hat ".tif"
	MetaTitel = substring (MetaInfo, 0, Titel_end); 	//Titel extrahieren von Position "0" bis ".tif"
		//print("MetaTitel:", MetaTitel);
	////////////////////////////////////////////////////
	
	//Position extrahieren//////////////////////////////
	Position_end = indexOf(MetaInfo, "_"); 				
	Position = substring (MetaInfo, 0, Position_end); 	
	//print("MetaTitel:", Position); 
	////////////////////////////////////////////////////

	/*Emission filter///////////////////////////////////
	Looks in the MetaInfos for the type of Emmsion filter and colors the image accordingly
	Looks for [title="Emission filter" value="Red"] if not present value=-1
	*/
	Emission = indexOf(MetaInfo, "title=\"Emission filter\" value=\"Red\""); 	
		//print("MetaTitel:", Emission);
		if (Emission!=-1) 
		{
			 run("Red");
			 wait(100);		//If no wait the LUT is not applied properly
 		} 
 	Emission = indexOf(MetaInfo, "title=\"Emission filter\" value=\"Green\""); 	
		//print("MetaTitel:", Emission);
		if (Emission!=-1) 
		{
			 run("Green");
			 wait(100);		//If no wait the LUT is not applied properly
 		} 
	////////////////////////////////////////////////////

	/*Coupling value///////////////////////////////////
	Looks in the MetaInfos for the coupling value
	Looks for [title="Coupling value" value="] if not present value=-1
	*/
	Coupling_start = indexOf(MetaInfo, "title=\"Coupling value\" value=");
	Coupling_start = Coupling_start + 30;	//increase start index to get rid of text in front of value
		//print("C_start:", Coupling_start);
	Coupling_end = indexOf(MetaInfo, "\"/><CouplingGrayFilter");
		//print("C_end:", Coupling_end);
		Coupling = substring (MetaInfo, Coupling_start, Coupling_end); 	//Titel extrahieren von Position "0" bis ".tif"
		//print("C:", Coupling);
	////////////////////////////////////////////////////

	/*Instrument///////////////////////////////////////
	Looks in the Titel for the Instrument Type
	Looks for [title="Coupling value" value="] if not present value=-1
	*/
	Instrument_start = indexOf(MetaTitel, "_Z");
	Instrument_start = Instrument_start + 1;	//increase start index to get rid of text in front of value
		//print("C_start:", Coupling_start);
	Instrument_end = Instrument_start + 2;
		//print("C_end:", Coupling_end);
		Instrument = substring (MetaTitel, Instrument_start, Instrument_end); 	//Titel extrahieren von Position "0" bis ".tif"
		//print("Instrument:", Instrument);
	////////////////////////////////////////////////////

	/*Draw Infos into image///////////////////////////////////
	*/
	setFont("Sanserif", 24);
	setColor("black");

  	drawString(Position, 10, 40, "white");
  	drawString("Coupling:" + Coupling, 50, 40, "white");
  	drawString("Min-Max:" + Min + "-" + Max, 230, 40, "white");
  	drawString(Instrument, 10, 80, "white");
  	wait(100);											//waiting for drawing
	////////////////////////////////////////////////////

 	saveAs("Jpeg", dir + "/" + MetaTitel);						//Speichern als JPG
	close();
	//file = dir + "/" + MetaTitel+".tif";
	//print("File:", file);


	/*Delete original tif Images/////////////////////////
	*/	
	if (Delete==true) File.delete(dir + "/" + MetaTitel+".tif");	
 	////////////////////////////////////////////////////
 	
 	i = i + 1; //counter for WHILE loop
} //End WHILE loop
 
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

/*Generation of Montage/////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
All images in directory are open again and the 
arranged in a Montage with 3 columns and variable 
rows
*/ 	
run("Image Sequence...", "open="+path+" convert_to_rgb sort");			//Reopen all jpg Image as Stack

columns = openImages / 3;
columns = -floor(-columns);  						//floor(x) rounds down, while -floor(-x) rounds up.
run("Make Montage...", "columns=3 rows="+columns+" scale=1.0");
saveAs("Jpeg", dir + "/Montage");						//Speichern als JPG
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


//Cleaning up///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
close();		//close Montage		
close();		//close Stack
//Closing Log Window/////////////////////////////
if (isOpen("Log")) { 
    selectWindow("Log"); 
    run("Close"); 
    } 
////////////////*Generation of Montage//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////