run("3D Manager V4 Macros"); // import 3DManager macro extension
Ext.Manager3DV4_ImportImage(); // import current label image
Ext.Manager3DV4_MeasureList(); // print the list of available measurements
Ext.Manager3DV4_GetClass(0, class); print("Class for object 0 "+class); // get the class of objet 0
Ext.Manager3DV4_SetClass(0, 1); // set the class of object 0
Ext.Manager3DV4_GetClass(0, type); print("Class for object 0 "+type); // get the class objet 0
measure =  "Volume(Unit)"; 
Ext.Manager3DV4_Measure(0, measure, mes); print(measure +" for object 0 "+mes); // performs measurement on object 0
measureInt =  "IntensityAvg";  // intensity measure in current image
Ext.Manager3DV4_MeasureIntensity(0, measureInt, mes); print(measureInt +" for object 0 "+mes); // performs measurement on object 0
Ext.Manager3DV4_NbObjects(nb); print("Number of objects "+nb); // get the total number of objects
for(i=0;i<nb;i++){ // loop for all object indices
    red = 128+random*127;
    green = 128+random*127;
    blue = 128+random*127;
    Ext.Manager3DV4_3DViewer(i, red, green, blue); // displays object i in 3D viewer with colour
}
// distances
Ext.Manager3DV4_DistanceList();
Ext.Manager3DV4_Distance2(0,1,"DistBorderBorderUnit",dist); print("Distance between 2 first objects "+dist);
print("Done");