//Written By Benjamin Escribano 04.04.2017 in order to analyse STED data!!!
//Welche Möglichkeiten zum Zwischenspeichern gibt es?

s=File.separator


Dialog.create("STED Analysis");
Dialog.addMessage("Parameters For Actve Zone Selection\n")
Dialog.addNumber("Width:", 51);
Dialog.addNumber("Height:", 51);
Dialog.addCheckbox("Select Active Zones", false);
Dialog.addCheckbox("Create AZ Stack", false);
Dialog.addCheckbox("Clean AZs", false);
Dialog.addCheckbox("Select AZ Core Region", false);
Dialog.addCheckbox("Measure AZ Diameter", false);
Dialog.addMessage("Parameters For Actve Zone Diameter Measurement:\n");
Dialog.addRadioButtonGroup("Extract from:", newArray("Raw", "Cleaned"), 1, 2, "Cleaned");
//Dialog.addRadioButtonGroup("Adaption of diameter lines:", newArray("manual", "automatic"), 1, 2, "manual");
Dialog.addRadioButtonGroup("Core recognition:", newArray("manual", "automatic"), 1, 2, "manual");
Dialog.addMessage("Parameters For BAR Peak Finder:\n");
Dialog.addNumber("Min. peak amplitude:", 15);
Dialog.addNumber("Min. peak distance:", 0);
Dialog.addNumber("Min. value of maxima:", 2);
Dialog.addNumber("Max. value of minima:", 0);
Dialog.addCheckbox("Exclude peaks on edges of plot", true);
Dialog.show();

width = Dialog.getNumber();
height = Dialog.getNumber();
select = Dialog.getCheckbox();
stack = Dialog.getCheckbox();
clean = Dialog.getCheckbox();
coreSel = Dialog.getCheckbox();
measure = Dialog.getCheckbox();
from = Dialog.getRadioButton();
//adapt = Dialog.getRadioButton();
core = Dialog.getRadioButton();
MinAmp = Dialog.getNumber();
MinDist = Dialog.getNumber();
MinMax = Dialog.getNumber();
MaxMin = Dialog.getNumber();
exclude = Dialog.getCheckbox();

if (exclude==true) exclude= "exclude";
if (exclude==false)	exclude= "";
if (MinMax==NaN) MinMax="[]";
if (MaxMin==NaN) MaxMin="[]";

inDir=getDirectory("Choose Input Folder");
File.makeDirectory(inDir+s+"Output");
File.makeDirectory(inDir+s+"Results");
outDir=inDir+s+"Output";
resDir=inDir+s+"Results";


list = getFileList(inDir);

if (select==true) {
	selectActiveZones();
}
run ("Close All");
if (stack==true) {
	makeStack();
}
run ("Close All");
if (clean==true) {
	cleanResidues();
}
run ("Close All");
if (coreSel==true) {
	selCoreReg();
}
run ("Close All");
if (measure==true) {
	measureDiameter();
}
run ("Close All");



function selectActiveZones () {
	for (i=0; i<list.length; i++) {
		if (endsWith(list[i], ".tif"))
			openAndSelect();
		//else print (list[i]);
	}
}

function openAndSelect () {
			setTool("rectangle");
			run("ROI Manager...");
			open(list[i]);
			makeRectangle(512, 512, width, height);
			waitForUser("Active Zone Selection", "Please add the Actve Zones to the Roi Manager");
			NumberOfRois=roiManager("count");	
			for (j=0; j<NumberOfRois; j++) {
				selectWindow(list[i]);
				roiManager("select",j);
				roiManager("rename", "Active Zone "+j);
				run("Duplicate...", " ");
				saveAs("TIFF", inDir+s+"Output"+s+list[i]+"Active Zone "+j);
				close();		
			}	
			roiManager("save", inDir+s+list[i]+".zip");
			roiManager("reset");
			selectWindow("ROI Manager");
			run("Close");
			close(list[i]);   
}

function makeStack()	{
	run("Image Sequence...", "open=["+outDir+"] sort use");
	saveAs("TIFF", resDir+s+"Active Zone Stack_Raw");
	close();
}

function cleanResidues(){
	open(resDir+s+"Active Zone Stack_Raw.tif");
	selectWindow("Active Zone Stack_Raw.tif");
	run("In [+]");
	run("In [+]");
	run("In [+]");
	run("In [+]");
	run("In [+]");
	run("In [+]");
	slices=nSlices;
	setForegroundColor(0, 0, 0);	
	for (k=1; k<=slices; k++){
		setTool("brush");
		setSlice(k);
		waitForUser("Cleaning Residues of other Active Zones", "Please clean out all the residual AZ material");
		run("Fill", "slice");		
	}
	saveAs("TIFF", resDir+s+"Active Zone Stack_Cleaned");
	close();
}

//Kann mann die zentrieren zum messen?
//automatisches oder manuelles anpassen?
//Welche measurement parameters gibt es?
//Bounding box?
//work with peaks/half height ful width measurement

function selCoreReg() {
	prepForMeasurement();	
	slices2=nSlices;
	run("ROI Manager...");
	roiManager("reset");
	for (l=1; l<=slices2; l++){
	if (core=="manual"){
		setSlice(l);
		manuCore();
		getSelectionCoordinates(x, y);
		roiManager("add");
		roiManager("select", ((l-1)*3)+0);
		roiManager("rename", "AZ "+l+"Core");
		horiLine();
		setTool("line");
		waitForUser("Diameter Measurement:", "If you are satisfied with the line klick OK. Else adapt the line please.");
		roiManager("add");
		roiManager("select", ((l-1)*3)+1);
		roiManager("rename", "AZ "+l+"HL");
		vertiLine ();
		setTool("line");
		waitForUser("Diameter Measurement:", "If you are satisfied with the line klick OK. Else adapt the line please.");
		roiManager("add");
		roiManager("select", ((l-1)*3)+2);
		roiManager("rename", "AZ "+l+"VL");	
	}
	}
	roiManager("save", resDir+s+"Active Zone Stack_"+from+" Core Selection"+".zip");
	close();
	roiManager("reset");
	selectWindow("ROI Manager");
    run("Close");
}

function prepForMeasurement (){
		open(resDir+s+"Active Zone Stack_"+from+".tif");
		selectWindow("Active Zone Stack_"+from+".tif");
		run("In [+]");
		run("In [+]");
		run("In [+]");
		run("In [+]");
		run("In [+]");
		run("In [+]");
}

function manuCore ()	{
	setTool("point");
	waitForUser("Diameter Measurement:", "Please choose the core of the ring. When done klick ok.");		
}

function horiLine ()	{
	makeLine(x[0]-(width/2), y[0], x[0]+(width/2), y[0]);
	//print(x[0]-15, y[0], x[0]+15, y[0]);
}

function vertiLine ()	{
	makeLine(x[0], y[0]-(height/2), x[0], y[0]+(height/2));
	//print(x[0], y[0]-15, x[0], y[0]+15);
}

function measureDiameter() {
	prepForMeasurement ();
	slices3=nSlices;
	run("ROI Manager...");
	roiManager("reset");
	roiManager("open", resDir+s+"Active Zone Stack_"+from+" Core Selection"+".zip")

	name1 = "[Average Diameter Calculation (AZ;Peak1.1;Peak1.2;Diameter1;Peak2.1;Peak2.2;Diameter2;AverageDiameter)]";
	run("New... ", "name="+name1+" type=Table");
 	D1 = name1;

 	print(D1, "\\Update"+0+":AZ	Peak1.1	Peak1.2	Dia1	Peak2.1	Peak2.2	Dia2	Average.Diameter");

	for (m=1; m<=slices3; m++){
		selectWindow("Active Zone Stack_"+from+".tif");
		setSlice(m);
		roiManager("select", ((m-1)*3)+1);
		run("Plot Profile");
		run("Find Peaks", "min._peak_amplitude="+MinAmp+" min._peak_distance="+MinDist+" min._value="+MinMax+" max._value="+MaxMin+" "+exclude+" list");
		selectWindow("Plot Values");
		Peak1_1 = getResult("X1", 0);
		Peak1_2 = getResult("X1", 1);
		run("Close");
		if (Peak1_1 > Peak1_2)	{
			Diameter1 = (Peak1_1 - Peak1_2);
		}
		else {
			Diameter1 = (Peak1_2 - Peak1_1);
		}
		close ("Plot of Active Zone Stack_"+from);
		close ("Peaks in Plot of Active Zone Stack_"+from);
		roiManager("select", ((m-1)*3)+2);
		run("Plot Profile");
		run("Find Peaks", "min._peak_amplitude="+MinAmp+" min._peak_distance="+MinDist+" min._value="+MinMax+" max._value="+MaxMin+" "+exclude+" list");
		selectWindow("Plot Values");
		Peak2_1 = getResult("X1", 0);
		Peak2_2 = getResult("X1", 1);
		run("Close");
		if (Peak2_1 > Peak2_2)	{
			Diameter2 = (Peak2_1 - Peak2_2);
		}
		else {
			Diameter2 = (Peak2_2 - Peak2_1);
		}
		close ("Plot of Active Zone Stack_"+from);
		close ("Peaks in Plot of Active Zone Stack_"+from);
		AverageDiameter = ((Diameter1+Diameter2)/2);

		print(D1, "\\Update"+m+":AZ "+m+"	"+Peak1_1+"	"+Peak1_2+"	"+Diameter1+"	"+Peak2_1+"	"+Peak2_2+"	"+Diameter2+"	"+AverageDiameter);		
		}
	selectWindow("Average Diameter Calculation (AZ;Peak1.1;Peak1.2;Diameter1;Peak2.1;Peak2.2;Diameter2;AverageDiameter)");
	saveAs("Text", resDir+s+"Average Diameter of the Active Zones Calculation.txt");
	run("Close");
	roiManager("reset");
	selectWindow("ROI Manager");
    run("Close");
    close("Active Zone Stack_"+from+".tif");
}