s=File.separator;
w=1;
h=1;
c=1;
slc=1;
f=1;

Dialog.create("Bruker Data Manager");
Dialog.addCheckbox("Input Directory = Output Directory", false);
Dialog.addMessage("Image Extraction from Raw Data:");
Dialog.addCheckbox("Extract Files from RAW Data", false);
Dialog.addMessage("(Make sure there are no RAWDATA Folders!)");
Dialog.addMessage("Delete Files:");
Dialog.addCheckbox("Delete Extracted Files", false);

Dialog.show();

inDisOutD=Dialog.getCheckbox();
Extr=Dialog.getCheckbox();
DelExtr=Dialog.getCheckbox();

inDir=getDirectory("Choose the Raw Data Containing Folder");

if (inDisOutD==true) {
	outDir=inDir;
}
else {
	outDir=getDirectory("Choose Output Folder");
	if ((inDir==outDir) || (startsWith(outDir, inDir))) {
	exit("Input folder must be different from and not within output folder!");
	}
}
inDir1=inDir;

setBatchMode(true);

if (Extr==true) {
	ExtractFiles(inDir);
}

if (DelExtr==true) {
	DeleteFiles(outDir);
}
setBatchMode(false);



function ExtractFiles(inDir) {
     list = getFileList(inDir);
     for (i=0; i<list.length; i++)     {
     	if (endsWith(list[i], "/")) {
     		Duplicate=replace(inDir+s+list[i], inDir1, outDir);
     		if (!File.exists(Duplicate)) {
     			File.makeDirectory(Duplicate);
     		}     		
     		if (endsWith(Duplicate, "MIP/") || endsWith(Duplicate, "References/")) {
     			File.delete(Duplicate);
     		}
     		ExtractFiles(inDir+list[i]);
     	}
     	else if (endsWith(list[i], ".xml"))	{
     		ExtractedFilePath=replace(inDir+s+list[i], inDir1, outDir);
     		ExtractedFile=replace(ExtractedFilePath, ".xml", "_Stack_Extr.tif");
     		if (!File.exists(ExtractedFile)) {
     			run("Bio-Formats", "open=["+inDir+list[i]+"] autoscale color_mode=Default rois_import=[ROI manager] view=Hyperstack stack_order=XYCZT");
     			name=File.getName(outDir+list[i]);
     			selectWindow(name);
     			getDimensions(w, h, c, slc, f);
     			if (f>1) {
     				Stack.setChannel(1);
					resetMinAndMax();
					Stack.setChannel(2);
					resetMinAndMax();
					saveAs("tiff", replace(ExtractedFilePath, ".xml", "_Stack_Extr.tif"));
     			}
     			else   {
     				saveAs("tiff", replace(ExtractedFilePath, ".xml", "_Extr.tif"));  			
     			}   			
     			run("Close All");
     			run("Collect Garbage");
     			close("Log");
     		}     		
     	}
     }
}

function DeleteFiles(outDir) {
	list = getFileList(outDir);
	for (i=0; i<list.length; i++) {
		if (endsWith(list[i], "/")) {
			DeleteFiles(outDir+list[i]);
		}
		else if (endsWith(list[i], "_Extr.tif")) {
			File.delete(outDir+list[i])		
		}					
	}
}