//script parameters
#@ File(label="Directory", style="directory") dir
#@ String (label="Apply", choices={"None", "8-bit", "Normalize"}, style="radioButtonHorizontal") apply
#@ String (label="Output", choices={"TIF", "HDF5"}, style="radioButtonHorizontal") format
#@ String (label="Extension", description="Enter the extension of the files to be transformed. Image extensions: tif, png, jpg, others...") extension
#@ String (label="Postfix", description="Enter a postfix to tag the output folder") postfix

print("\\Clear");
original=File.getName(dir);
list=getFileList(dir);
output=File.getParent(dir)+File.separator+original+"_"+postfix;

//check if the folder contains the specified files
count=0;
for (i=0; i<list.length; i++) {
	if (endsWith(list[i], extension)==true) {
		count++;
	}
}

//error message
if (count==0) {
	exit("No "+extension+" files found in "+original);
}

//create the output folder
print("Macro starts");
File.makeDirectory(output);

//convert the image datset into tif files with a bit depth of 8-bit
setBatchMode(true);
for (i=0; i<list.length; i++) {
	print(list[i], i+1 + "/" + list.length);
	open(dir+File.separator+list[i]);
	name=File.nameWithoutExtension;
	rename(name);
	if (apply == "8-bit") {
		run("8-bit");
	} else if (apply == "Normalize") {
		run("32-bit");
		run("Enhance Contrast...", "saturated=0.1 normalize");
	}
	if (format == "TIF") {
		saveAs("tif", output+File.separator+name);
		close(name+".tif");
	} else {
		run("Export HDF5", "select=["+output+File.separator+name+".h5] exportpath=["+output+File.separator+name+".h5] datasetname=data compressionlevel=0 input=["+name+"]");
		close();
	}
}
setBatchMode(false);
print("Macro ends");