/*Instructions:
Please note that this macro is designed for analyzing images collected through an image splitter in which two channels
display in the same image.
The macro assumes you have collected an data set for background subtraction and that these data are 
in the same directory with the rest of the images.  It is not necessary for them to be in the same sub-directory.  If it runs properly,
the macro should be able to search all subdirectories of the one returned from the prompt "Where are the files?" and return filepaths for ".tifs".
If your image files have different extensions, you'll have to edit the macro below.
A new folder for the analyzed data for each channel will be made inside the folder selected with the prompt "Where should the files be stored?".
These are image chnanels.  The data for ROIs made for the channels on different sides of the same image will be designated "green" or "red".
Another curve fitting macro will store the rate constant information etc. in this folder.
The macro is designed to analyze all the experiments performed at the same power level.
You may select up to 10.
The name of the first non-background file selected in the GUI will be automatically selected
 as the basename throughout the analysis.  
At the end, files for each channel at each power setting will made with a name appended
with "_raw_values_channel_XX.txt" and "_normalized_channel_XX.txt"  In the curve fitting macro
choose the normalized version for analysis.  Both are txt images which can be opened in 
text editing programs, Excel, or probably a number of softwares.
Please note that each experiment has a corresponding time column (even numbers if counting starting with 0)
Experimental columns are even number starting with 1.  Please note that column number 1 in all of these txt images 
represent the raw background value which were subtracted from the experimental columns.
*/



macro"PSFRET analysis"{
run("Bio-Formats Macro Extensions");
//print("\\Clear");
roiManager("Reset");
run("Set Measurements...", "redirect=None decimal=9");
dir0=getDirectory("Where are the files?");
dir1=getDirectory("Where should the files be stored?");

startTime=getTime();
setBatchMode(false);


dir0list=getFileList(dir0);
ListOfFiles=newArray("None");
ListOfDirs=newArray("None");
for(i=0;i<dir0list.length;i++){
if(endsWith(dir0list[i] , ".tif")){
ListOfFiles=appendToArray(dir0list[i], ListOfFiles);
ListOfDirs=appendToArray(dir0, ListOfDirs);
}
if(File.isDirectory(dir0+dir0list[i])==true){
dir00list=getFileList(dir0+dir0list[i]);
for(ii=0;ii<dir00list.length;ii++){
if(endsWith(dir00list[ii] , ".tif")){
ListOfFiles=appendToArray(dir00list[ii], ListOfFiles);
ListOfDirs=appendToArray(dir0+dir0list[i], ListOfDirs);
}
}
}
}


Dialog.create("PS-FRET analysis");
Dialog.addChoice("Choose the background stack",ListOfFiles);
Dialog.addMessage("");
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.addChoice("Choose an experiment stack",ListOfFiles);
Dialog.show();

bkgrd=Dialog.getChoice();
expt0=Dialog.getChoice();
expt1=Dialog.getChoice();
expt2=Dialog.getChoice();
expt3=Dialog.getChoice();
expt4=Dialog.getChoice();
expt5=Dialog.getChoice();
expt6=Dialog.getChoice();
expt7=Dialog.getChoice();
expt8=Dialog.getChoice();
expt9=Dialog.getChoice();

tempAnalyzeThese=newArray(bkgrd,expt0,expt1,expt2,expt3,expt4,expt5,expt6,expt7,expt8,expt9);

AnalyzeThese=newArray(0);
AnalyzeTheseFullPath=newArray(0);

for(i=0;i<tempAnalyzeThese.length;i++){
if(tempAnalyzeThese[i]!="None"){
AnalyzeThese=appendToArray(tempAnalyzeThese[i],AnalyzeThese);
}
}

for(i=0;i<AnalyzeThese.length;i++){
for(j=0;j<ListOfFiles.length;j++){
if(ListOfFiles[j]==AnalyzeThese[i]){
fullPath=ListOfDirs[j]+ListOfFiles[j];
AnalyzeTheseFullPath=appendToArray(fullPath,AnalyzeTheseFullPath);
}
}
}
Ext.setId(AnalyzeTheseFullPath[1]);
Ext.getSeriesName(DataFileName);

Ext.getSizeX(width);
Ext.getSizeY(height);
Ext.getSizeC(channels);
Ext.getSizeZ(slices);
Ext.getSizeT(frames);

if(channels==1){
if(File.exists(dir1+"Channel1")!=true){
File.makeDirectory(dir1+"Channel1");
}
dirCh1 = dir1+"Channel1"+File.separator;
ChannelsDirArray=newArray();
ChannelsDirArray=appendToArray(dirCh1, ChannelsDirArray);
}
if(channels==2){
if(File.exists(dir1+"Channel1")!=true){
File.makeDirectory(dir1+"Channel1");
}
dirCh1 = dir1+"Channel1"+File.separator;
if(File.exists(dir1+"Channel2")!=true){
File.makeDirectory(dir1+"Channel2");
}
dirCh2 = dir1+"Channel2"+File.separator;
ChannelsDirArray=newArray(dirCh1,dirCh2);
}
if(channels==3){
if(File.exists(dir1+"Channel1")!=true){
File.makeDirectory(dir1+"Channel1");
}
dirCh1 = dir1+"Channel1"+File.separator;
if(File.exists(dir1+"Channel2")!=true){
File.makeDirectory(dir1+"Channel2");
}
dirCh2 = dir1+"Channel2"+File.separator;
if(File.exists(dir1+"Channel3")!=true){
File.makeDirectory(dir1+"Channel3");
}
dirCh3 = dir1+"Channel3"+File.separator;
ChannelsDirArray=newArray(dirCh1,dirCh2,dirCh3);
}
if(channels==4){
if(File.exists(dir1+"Channel1")!=true){
File.makeDirectory(dir1+"Channel1");
}
dirCh1 = dir1+"Channel1"+File.separator;
if(File.exists(dir1+"Channel2")!=true){
File.makeDirectory(dir1+"Channel2");
}
dirCh2 = dir1+"Channel2"+File.separator;
if(File.exists(dir1+"Channel3")!=true){
File.makeDirectory(dir1+"Channel3");
}
dirCh3 = dir1+"Channel3"+File.separator;
if(File.exists(dir1+"Channel4")!=true){
File.makeDirectory(dir1+"Channel4");
}
dirCh4 = dir1+"Channel4"+File.separator;
ChannelsDirArray=newArray(dirCh1,dirCh2,dirCh3,dirCh4);
}


//print("\\Clear");

for(k=0;k<AnalyzeThese.length;k++){
Ext.setId(AnalyzeTheseFullPath[k]);
run("Bio-Formats", "open=["+AnalyzeTheseFullPath[k]+"] autoscale color_mode=Default split_focal view=Hyperstack stack_order=XYCZT");
OpenStack=getImageID;
selectImage(OpenStack);

//make some ROIs in one of the channels; then we'll copy to the other channel
run("ROI Manager...");
roiManager("Show All");
waitForUser("ROI","Please draw some ROIs in the channel of your choice and click Add in the ROI Manager");
while(roiManager("count")<=0){
waitForUser("ROI","Please draw some ROIs in the channel of your choice and click Add in the ROI Manager");
}
roiManager("select",0);
Roi.getBounds(xStart,yStart,ROIwidth,ROIheight);
startingCount=roiManager("count");
//array to select the new ROIs
chkROIArray=newArray(startingCount);
greenROIArray=newArray(startingCount);
redROIArray=newArray(startingCount);
if(yStart>=height/2){//these were made in the green channel
	for(roiIndex=0;roiIndex<startingCount;roiIndex++){
		roiManager("Select",roiIndex);
		roiManager("Rename", "Expt_"+k+"_GreenROI_cell_"+roiIndex);
		greenROIArray[roiIndex]=roiManager("index");		
		Roi.getBounds(startX,startY,widthROI,heightROI);
		typeOfSelection=selectionType();
		getSelectionCoordinates(xpoints, ypoints);
		makeSelection(typeOfSelection, xpoints, ypoints);
		Roi.move(startX+9, startY-216);
		roiManager("Add");
		roiManager("Select",roiIndex+startingCount);
		roiManager("Rename", "Expt_"+k+"_RedROI_cell_"+roiIndex);
		redROIArray[roiIndex]=roiManager("index");		
		chkROIArray[roiIndex]=roiManager("index");
	}
}else{//these were made in the red channel
	for(roiIndex=0;roiIndex<startingCount;roiIndex++){
		roiManager("Select",roiIndex);
		roiManager("Rename", "Expt_"+k+"_RedROI_cell_"+roiIndex);
		redROIArray[roiIndex]=roiManager("index");		
		Roi.getBounds(startX,startY,widthROI,heightROI);
		typeOfSelection=selectionType();
		getSelectionCoordinates(xpoints, ypoints);
		makeSelection(typeOfSelection, xpoints, ypoints);
		Roi.move(startX-9, startY+216);
		roiManager("Add");
		roiManager("Select",roiIndex+startingCount);
		roiManager("Rename", "Expt_"+k+"_GreenROI_cell_"+roiIndex);
		greenROIArray[roiIndex]=roiManager("index");		
		chkROIArray[roiIndex]=roiManager("index");
	}	
}
roiManager("select",chkROIArray);
newROIsOK=false;

channelToDisplay=3;
frameToDisplay=1;
sliceToDisplay=1;
maxIntensity=pow(2,bitDepth());
newIntensity=maxIntensity;
while(newROIsOK==false){
	Dialog.create("Check the new ROIs");
	Dialog.addCheckbox("Are the ROIs OK?", false);
	Dialog.addNumber("Translate ROIs x direction ? pixels",0);
	Dialog.addNumber("Translate ROIs y direction ? pixels",0);
	Dialog.addSlider("Channels",1,channels,channelToDisplay);
	Dialog.addSlider("Frames",1,frames,frameToDisplay);
	Dialog.addSlider("Slices",1,slices,sliceToDisplay);
	Dialog.addSlider("Contrast",0,maxIntensity,newIntensity);
	Dialog.show();
	newROIsOK=Dialog.getCheckbox();
	xTranslate=Dialog.getNumber();
	yTranslate=Dialog.getNumber();
	channelToDisplay=Dialog.getNumber();
	frameToDisplay=Dialog.getNumber();
	sliceToDisplay=Dialog.getNumber();
	newIntensity=Dialog.getNumber();
	if(newROIsOK==false)
	roiManager("translate",xTranslate,yTranslate);
	Stack.setChannel(channelToDisplay);
	Stack.setFrame(frameToDisplay);
	Stack.setSlice(sliceToDisplay);
	setMinAndMax(0,newIntensity);
}



for(i=1;i<=channels;i++){
selectImage(OpenStack);
Stack.setChannel(i);

//********get the time stamps
imageTimesArray=newArray(frames);
for(j=i-1;j<frames*channels;j+=channels){
Ext.getPlaneTimingDeltaT(deltaT,j);
imageTimesArray[j/channels]=deltaT;
}


//***********quantify green channel of the dualview
if(isOpen("Channel_"+i+"_GreenROIs"))
IJ.renameResults("Channel_"+i+"_GreenROIs","Results");
selectImage(OpenStack);
for(j=1;j<=frames;j++){
for(gROI=0;gROI<greenROIArray.length;gROI++){
roiManager("select",greenROIArray[gROI]);
roiManager("remove slice info");
roiManager("remove frame info");
roiManager("remove channel info");
Stack.setFrame(j);
Stack.setChannel(i);
getStatistics(area,mean);
roiName=call("ij.plugin.frame.RoiManager.getName", greenROIArray[gROI]);
setResult(roiName+"_time",j-1,imageTimesArray[j-1]);
setResult(roiName,j-1,mean);
}
}
IJ.renameResults("Results","Channel_"+i+"_GreenROIs");


//***********quantify red channel of the dualview
if(isOpen("Channel_"+i+"_RedROIs"))
IJ.renameResults("Channel_"+i+"_RedROIs","Results");
selectImage(OpenStack);
for(j=1;j<=frames;j++){
for(rROI=0;rROI<redROIArray.length;rROI++){
roiManager("select",redROIArray[rROI]);
roiManager("remove slice info");
roiManager("remove frame info");
roiManager("remove channel info");
Stack.setFrame(j);
Stack.setChannel(i);
getStatistics(area,mean);
roiName=call("ij.plugin.frame.RoiManager.getName", redROIArray[rROI]);
setResult(roiName+"_time",j-1,imageTimesArray[j-1]);
setResult(roiName,j-1,mean);
}
}
IJ.renameResults("Results","Channel_"+i+"_RedROIs");
}//end for(i=1;i<=channels;i++){

selectImage(OpenStack);
close();
roiManager("Deselect");
roiManager("Save",File.getParent(AnalyzeTheseFullPath[k])+File.separator+File.getName(AnalyzeTheseFullPath[k])+"_ROIset.zip");
roiManager("Reset");
}//for(k=0;k<AnalyzeThese.length;k++){


//*******background subtractions and save **************

for(i=1;i<=channels;i++){
//**** green bkgrd ************
if(isOpen("Channel_"+i+"_GreenROIs"))
IJ.renameResults("Channel_"+i+"_GreenROIs","Results");
gheadings=split(String.getResultsHeadings);
for(j=0;j<nResults;j++){
bkgrdMeanG=getResult(gheadings[1],j);
for(gROI=3;gROI<gheadings.length;gROI+=2){
gMean=getResult(gheadings[gROI],j);
gMeanBkSub=gMean-bkgrdMeanG;
setResult(gheadings[gROI],j,gMeanBkSub);
}
}
selectWindow("Results");
saveAs(ChannelsDirArray[i-1]+DataFileName+"_green_raw_values_channel_"+i+".txt");

for(gROI=3;gROI<gheadings.length;gROI+=2){
gMeanMax=getResult(gheadings[gROI],0);
for(j=0;j<nResults;j++){
gMean=getResult(gheadings[gROI],j);
normGMean=gMean*1/gMeanMax;
setResult(gheadings[gROI],j,normGMean);
}
}
selectWindow("Results");
saveAs(ChannelsDirArray[i-1]+DataFileName+"_green_normalized_values_channel_"+i+".txt");
run("Close");

//**** red bkgrd ************
if(isOpen("Channel_"+i+"_RedROIs"))
IJ.renameResults("Channel_"+i+"_RedROIs","Results");
rheadings=split(String.getResultsHeadings);
for(j=0;j<nResults;j++){
bkgrdMeanR=getResult(rheadings[1],j);
for(rROI=3;rROI<rheadings.length;rROI+=2){
rMean=getResult(rheadings[rROI],j);
rMeanBkSub=rMean-bkgrdMeanR;
setResult(rheadings[rROI],j,rMeanBkSub);
}
}
selectWindow("Results");
saveAs(ChannelsDirArray[i-1]+DataFileName+"_red_raw_values_channel_"+i+".txt");

for(rROI=3;rROI<rheadings.length;rROI+=2){
rMeanMax=getResult(rheadings[rROI],0);
for(j=0;j<nResults;j++){
rMean=getResult(rheadings[rROI],j);
normRMean=rMean*1/rMeanMax;
setResult(rheadings[rROI],j,normRMean);
}
}
selectWindow("Results");
saveAs(ChannelsDirArray[i-1]+DataFileName+"_red_normalized_values_channel_"+i+".txt");
run("Close");
}//for(i=1;i<=channels;i++)





setBatchMode(false);
stopTime=getTime();
timeRequiredMin=(stopTime-startTime)/(1000*60);
timeRequiredSec=(stopTime-startTime)/(1000);
timeRequiredMinutes=floor(timeRequiredMin);
timeRequiredSeconds=timeRequiredSec-(timeRequiredMinutes*60);
//print("time required ="+timeRequiredMinutes+" minutes "+timeRequiredSeconds+" seconds");


function appendToArray(value, array) {
temparray=newArray(lengthOf(array)+1);
for(i=0;i<lengthOf(array);i++){
temparray[i]=array[i];
}
temparray[lengthOf(temparray)-1]=value;
array=temparray;
return array;
}

}//end of macro