//////////////////////////////////////////////////////////////////////
//									//
//	PASCAL! 							//
//	Perineuronal net Automation Software for 			//
//	Computation and Analysis of Labeling				//
//									//
//	Written by John H. Harkness, Ph.D.				//
//	>>> Contact: harknessjh@gmail.com				//
//	>>> Copyright (C) 2016, John H. Harkness			//
//									//
//	Washington State University, Vancouver			//
//									//
//	Supported by:							//
//	>>> WSU Alcohol and Drug Abuse Research Program (ADARP)	//
//	>>> The Translational Addiction Research Center (TARC)	//
//	>>> NIH DA 033404	 					// 
//	>>> Washington State Initiative Measure No. 171		//
//									//
//	Protocol based on Slaker, Harkness, and Sorg, 2016		//
//	>>> Special thanks to Megan Slaker				//
//									//
//    >>> PLEASE CITE: Slaker, et al., 2016 (IN SUBMISSION) <<<	//
//									//
//////////////////////////////////////////////////////////////////////


	//Global variables

var lower=0;
var import_type=0;
var first_open = 0;
var last_open = 0;
var name = 0;
var full_name = 0;
var dir = 0;
var first_time = 0;
var save_location = 0;
var countCount = 0;


///////////////////////////

macro "PASCAL" {

Dialog.create("Welcome.");
items = newArray("Count labeled cells.", "Single label intensity analysis.");
Dialog.addRadioButtonGroup("What would you like to do?", items, 2, 1, "Single label intensity analysis.");
Dialog.show;
choice = Dialog.getRadioButton;
if (choice=="Count labeled cells.") {
       run("__sub_PASCAL_count");
	
	} else {
	if (choice=="Single label intensity analysis.") {
		run("__sub_PASCAL_single");
		}
	}
}

//////////////////////////

macro "__sub_PASCAL_count" {
	//count labeled cells

import_type=4;

countCount = 1
countCount++
if (countCount == 2) {
	Dialog.create("Count Labeled Cells.");
	items = newArray("Yes, continue.", "No. Go back to make summed z-stacks before continuing.");
	Dialog.addRadioButtonGroup("For this analysis, you will import previously summed z-stacks for automated counting of labeled cells. \n Do you 	have summed files ready?", items, 2, 1, "Yes, continue.");
	Dialog.show;
	choice = Dialog.getRadioButton;
	if (choice=="No. Go back to make summed z-stacks before continuing.") {
			run("PASCAL");
		} else {
			wait(1);
		}
	} else {
		wait(1);
		}
open();
run("Set Measurements...", "area mean standard min redirect=None decimal=3");
run("Set Scale...", "distance=1.194 known=1 pixel=1 unit=um global");
dir = getDirectory("image"); 
print(dir);
name = getTitle; 
full_name = getTitle; 
index = lastIndexOf(name, "."); 
if (index!=-1) name = substring(name, 0, index);
print("\n"+name+" loaded.");

first_open = name;


run("__sub_PASCAL_BackgroundAndROIs");
}

//////////////////////////

macro "__sub_PASCAL_single" {
       
print("PASCAL! Perineuronal net Intensity Program Specifically Quantifying ECMs Automatically.");
print("\n"+"Copyright (C) 2016, John H. Harkness, PhD");
print("Protocol by Megan Slaker");
print("Lab of Barb Sorg, Washington State University, Vancouver");
wait(1000);
Dialog.create("Import Type");
items = newArray("Semiautomated analysis of raw, non-summed, individual Tiffs", "Semiautomated analysis of summed Z-stack", "Automatic analysis of summed Z-stacks","\n___________________________________________\n\nMake summed image from z-stacks.\n\n\n");
Dialog.addRadioButtonGroup("What type of file do you want to import?", items, 4, 1, "Raw, non-summed, individual Tiffs");
Dialog.show;
choice = Dialog.getRadioButton;
if (choice=="Semiautomated analysis of raw, non-summed, individual Tiffs") {
       run("__sub_PASCAL_Import");
	
} else {
	if (choice=="Semiautomated analysis of summed Z-stack") {
		run("__sub_PASCAL_Import_Summed");
		}
	if (choice=="Automatic analysis of summed Z-stacks") {
		run("__sub_PASCAL_Auto_Import_Summed");
		}
	if (choice=="\n___________________________________________\n\nMake summed image from z-stacks.\n\n\n") {
		run("__sub_PASCAL_z-project");
		}
	}
}
/////////////////////////////

macro "__sub_PASCAL_Import" {
       // Importing stacks
import_type=1;
run("Image Sequence...", "disable_global convert sort");
selectWindow("Stacks");
run("Set Measurements...", "area mean standard min redirect=None decimal=3");

run("Z Project...", "projection=[Sum Slices]");
run("Set Scale...", "distance=1.194 known=1 pixel=1 unit=um global");
name = File.getName(File.directory);
full_name = "SUM_Stacks"; 
print("\n"+name+" loaded.");
run("__sub_PASCAL_BackgroundAndROIs");
}

/////////////////////////////

macro "__sub_PASCAL_Import_Summed" {
       // Importing image

import_type=2;
open();
run("Set Measurements...", "area mean standard min redirect=None decimal=3");
run("Set Scale...", "distance=1.194 known=1 pixel=1 unit=um global");
dir = getDirectory("image"); 
print(dir);
name = getTitle; 
full_name = getTitle; 
index = lastIndexOf(name, "."); 
if (index!=-1) name = substring(name, 0, index);
print("\n"+name+" loaded.");

first_open = name;


run("__sub_PASCAL_BackgroundAndROIs");
}

////////////////////////////////

macro "__sub_PASCAL_Auto_Import_Summed" {
       // Importing image

import_type=3;
open();
run("Set Measurements...", "area mean standard min redirect=None decimal=3");
run("Set Scale...", "distance=1.194 known=1 pixel=1 unit=um global");
dir = getDirectory("image"); 
name = getTitle;
full_name = getTitle; 
index = lastIndexOf(name, "."); 
if (index!=-1) name = substring(name, 0, index);
print("\n"+name+" loaded.");

first_open = name;

waitForUser("Please don't touch", "Please let the macro run without clicking windows. Disruption may cause the macro to stall.");

run("__sub_PASCAL_BackgroundAndROIs");
}

////////////////////////////////

macro "__sub_PASCAL_z-project" {
	//makes summed image from z-stack


top_dir = getDirectory("Choose a Directory ");
count = 1;
listFiles(top_dir); 


function listFiles(top_dir) {
	list = getFileList(top_dir+"/..");
	parentlist = File.getParent(top_dir);
	for (i=0; i<list.length; i++) {
		    	if (endsWith(list[i], ".tif")){
    	
        	listFiles(""+parentlist+File.separator+list[i]);

	} else {
			child_list = getFileList(parentlist+File.separator+ list[i]);
			for (a=0; a<child_list.length; a++) {
        		if (endsWith(child_list[a], ".tif")){
           			listFiles(""+child_list[a]);
			}else{
           			open_list = parentlist+File.separator+list[i]+child_list[a];
           			print("\n"+"Image total: "+(count++)+"= "+open_list);
           			run("Image Sequence...", "open=&open_list disable_global convert sort");
           			run("Set Measurements...", "area mean standard min redirect=None decimal=3");
					run("Z Project...", "projection=[Sum Slices]");
					run("Set Scale...", "distance=1.194 known=1 pixel=1 unit=um global");
					name = getTitle;
					file_name = File.getName(list[i]);
					folder_name = File.getName(File.getParent(File.directory));
					
						if (count == 2) {
							save_location = "/Users/John 1/Desktop/";
							Dialog.create("Save location");
							Dialog.addMessage("Select a place to save the summed image. ie, /Users/John/Desktop");
							Dialog.addString("Save to: ", save_location);
							Dialog.show();
							save_location = Dialog.getString();
							print("Save location: "+save_location);
						} else {
							wait(1);
							}

						if (File.exists(save_location+"PASCAL_Summed Stacks/")) {
							wait(1);
						} else { 
							File.makeDirectory(save_location+"PASCAL_Summed Stacks/");
							}
						saveAs("Tiff", save_location+"PASCAL_Summed Stacks/"+file_name+"-"+name+".tif");
						close(file_name+"-"+name+".tif");
						print("Image: "+file_name+"-"+name+"\n"+"Saved in: "+save_location+"PASCAL_Summed Stacks/");
						run("Close All");
					
	}
	}
}
}
}
Dialog.create("Again?");
items = newArray("Yes, save another.", "No, let's analyze.", "Exit");
Dialog.addRadioButtonGroup("Would you like to save another summed image?", items, 3, 1, "Yes, save another.");
Dialog.show;
choice = Dialog.getRadioButton;
if (choice=="Yes, save another.") {
       run("__sub_PASCAL_z-project");
	
	} else {
	if (choice=="No, let's analyze.") {
		run("PASCAL");
		}
	if (choice=="Exit") {
		print("\n"+"Thanks for using PASCAL. Bye!");
		}
	}
}

////////////////////////////////

macro "__sub_PASCAL_Open_Next_Summed" {

import_type=3;
makeRectangle(0, 0, 0, 0);
run("Revert");
run("Open Next");
run("Set Measurements...", "area mean standard min redirect=None decimal=3");
run("Set Scale...", "distance=1.194 known=1 pixel=1 unit=um global");
dir = getDirectory("image"); 
name = getTitle; 
full_name = getTitle; 
index = lastIndexOf(name, "."); 
if (index!=-1) name = substring(name, 0, index);
last_open = name;

if (last_open==first_open) {
	print("\n"+"All images processed! Done.");
	//makeRectangle(0, 0, 0, 0);
	//run("Revert");
	//run("Clear Results");
	//selectWindow("ROI Manager");
	run("Close");
	//selectWindow("Results");
	run("Close");
	//selectWindow(name+".tif");
	//selectWindow("Threshold");
	run("Close");
	run("Close");
} else {
	print ("\n"+last_open+" loaded.");
	run ("__sub_PASCAL_BackgroundAndROIs");
	}
}
///////////////////////////////

macro "__sub_PASCAL_BackgroundAndROIs" {
	// Selecting Background


run("Clear Results");

run("ROI Manager...");
roiManager("Show All");
roiManager("Show All with labels");
makeRectangle(475, 10, 30, 30);
roiManager("Add");
makeRectangle(475, 104, 30, 30);
roiManager("Add");
makeRectangle(475, 198, 30, 30);
roiManager("Add");
makeRectangle(475, 292, 30, 30);
roiManager("Add");
makeRectangle(475, 390, 30, 30)
roiManager("Add");
makeRectangle(475, 475, 30, 30);
roiManager("Add");
makeRectangle(407, 475, 30, 30);
roiManager("Add");
makeRectangle(324, 475, 30, 30);
roiManager("Add");
makeRectangle(246, 475, 30, 30);
roiManager("Add");
makeRectangle(167, 475, 30, 30);
roiManager("Add");
makeRectangle(89, 475, 30, 30);
roiManager("Add");
makeRectangle(10, 475, 30, 30);
roiManager("Add");
makeRectangle(10, 390, 30, 30);
roiManager("Add");
makeRectangle(10, 292, 30, 30);
roiManager("Add");
makeRectangle(10, 198, 30, 30);
roiManager("Add");
makeRectangle(10, 104, 30, 30);
roiManager("Add");
makeRectangle(10, 10, 30, 30);
roiManager("Add");
makeRectangle(89, 10, 30, 30);
roiManager("Add");
makeRectangle(167, 10, 30, 30);
roiManager("Add");
makeRectangle(246, 10, 30, 30);
roiManager("Add");
makeRectangle(324, 10, 30, 30);
roiManager("Add");
makeRectangle(407, 10, 30, 30);
roiManager("Add");
run("Subtract Background...", "rolling=10");
roiManager("Select", newArray(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,21));
roiManager("Measure");


	// Calculating lower threshold background value in "Mean" column

m=0;
bkgd_mean=0;
meanbkgd=0;
std=0;
bkgd_std=0;
stdbkgd=0;

m = nResults;
bkgd_mean = newArray(m);
run("Select None");
    for (i=0; i<m; i++) {
     bkgd_mean[i] = getResult('Mean', i);
    }
Array.getStatistics(bkgd_mean, min, max, mean, stdDev);
Array.sort(bkgd_mean);
bkgd_high_trim = Array.trim(bkgd_mean, 15);
Array.getStatistics(bkgd_high_trim, min, max, mean, stdDev);
Array.reverse(bkgd_high_trim);
bkgd_low_trim = Array.trim(bkgd_high_trim, 7);
Array.getStatistics(bkgd_low_trim, min, max, mean, stdDev);
meanbkgd = mean;

std = nResults;
bkgd_std = newArray(std);
run("Select None");
    for (i=0; i<std; i++) {
     bkgd_std[i] = getResult('StdDev', i);
    }
Array.getStatistics(bkgd_std, min, max, mean, stdDev);
Array.sort(bkgd_std);
bksd_high_trim = Array.trim(bkgd_std, 15);
Array.getStatistics(bksd_high_trim, min, max, mean, stdDev);
Array.reverse(bksd_high_trim);
bksd_low_trim = Array.trim(bksd_high_trim, 7);
Array.getStatistics(bksd_low_trim, min, max, mean, stdDev);
stdbkgd = mean;

lower = ((meanbkgd)+(stdbkgd*2));
print("Mean = "+meanbkgd+", StdDev = "+stdbkgd);
print("Lower Threshold= "+lower);

if (import_type==4) {
		run("__sub_PASCAL_count_ROIs");
	} else {

	// Setting Threshold

		run("Set Measurements...", "area mean standard min limit redirect=None decimal=3");
		setAutoThreshold("Default dark");
		run("Threshold...");
		wait(100);
		setThreshold(lower, 5000);
		//run("Apply");
		run("NaN Background");
		run("Close");
	}


	// Measuring ROIs
           //Finding PNNs with Analyze Particles

run("Clear Results");
wait(200);
setAutoThreshold("Default dark");
run("Threshold...");
setThreshold(lower*1.165, 5000);
wait(200);
makeRectangle(0, 0, 0, 0);
run("Analyze Particles...", "size=70-999999 circularity=0.02-1.00 clear include add");
wait(200);
selectWindow("Threshold");
resetThreshold();
roiManager("Measure");

           //Making square ROIs from Particles

wait(500);
add_squares=roiManager("count"); 
if (add_squares==0) {
		waitForUser("Oops", "We didn't see any PNNs here. Here is your chance to adjust the ROIs to better identify PNNs. Try adding ROIs in the ROI manager. **THEN** press OK.");
		} else {
		array=newArray(add_squares); 
		for(i=0; i<add_squares;i++) { 
		roiManager("Select", 0);
        	run("Specify...", "centered scaled");
        	run("Enlarge...", "enlarge=6");
        	roiManager("Add");
        	roiManager("Select", 0);
        	roiManager("Delete");
		} 

if (import_type==3) {
	wait(300);
} else {
	if (import_type==2) {
		run("Duplicate...", " ");
		selectWindow(full_name);
		run("Revert", " ");
		waitForUser("How Does That Look?", "Here is your chance to adjust the ROIs to better identify PNNs. Try adding or deleting ROIs in the ROI manager. **THEN** press OK.");
		selectWindow(full_name);
		run("Close");
		}
	if (import_type==1) {
		selectWindow("Stacks");
		run("Z Project...", "projection=[Sum Slices]");
		selectWindow("Stacks");
		close("Stacks");
		selectWindow(full_name+"-1");
		roiManager("Show All");
		roiManager("Show All with labels");
		waitForUser("How Does That Look?", "Here is your chance to adjust the ROIs to better identify PNNs. Try adding or deleting ROIs in the ROI manager. **THEN** press OK.");
		selectWindow(full_name+"-1");
		close(full_name+"-1");
		}
	}

run("Clear Results");
measure_squares=0;
measure_squares=roiManager("count"); 
array=newArray(measure_squares); 
for(i=0; i<measure_squares;i++) { 
        array[i] = i; 
}
roiManager("Select", array);
roiManager("Measure");
roiManager("Show All");
roiManager("Show All with labels");

m=0;
means=0;
m = nResults;
means = newArray(m);
run("Select None");
    for (i=0; i<m; i++) {
      means[i] = getResult('Mean', i);
    }
run("Select None");
    for (i=0; i<m; i++) {
      setResult("Background", i, lower);
      setResult("Mean-Background", i, means[i]-lower);
    }
setResult("File Name", 0, name);
updateResults();

m2 = 0;
avgmeans = 0;
m2 = nResults;
avgmeans = newArray(m2);
run("Select None");
    for (i=0; i<m2; i++) {
      avgmeans[i] = getResult('Mean-Background', i);
    }
Array.getStatistics(avgmeans, min, max, mean, stdDev);
print("Mean Intensity = "+mean);


numberPNNs=0;
numberPNNs=getValue("results.count");
print("Number of PNNs = "+numberPNNs);


if (import_type==3) {
	run("__sub_PASCAL_Save");
} else {
	waitForUser("Copy data?", "Results will be saved. You may also copy them to the clipboard. **THEN** press OK.");
	run("__sub_PASCAL_Save");
	}
}

/////////////////////////////

macro "__sub_PASCAL_count_ROIs" {
       // count labeled cells by making ROIs
           //Finding cells with Analyze Particles


roiManager("Delete");
run("Clear Results");

wait(100);
setAutoThreshold("Default dark");
run("Threshold...");
setThreshold(lower*0.5, 5000);
wait(200);
makeRectangle(0, 0, 0, 0);
run("Analyze Particles...", "size=20-999999 circularity=0.02-1.00 clear include add");
wait(200);
selectWindow("Threshold");
resetThreshold();

wait(500);
waitForUser("How Does That Look?", "Here is your chance to adjust ROIs to better count labeled cells. Try adding or deleting circular ROIs in the ROI manager. **THEN** press OK.");

roiManager("Measure");
numbercells=0;
numbercells=getValue("results.count");
print("Number of cells counted = "+numbercells);

run("Clear Results");
clear_ROIs=roiManager("count"); 
array=newArray(clear_ROIs); 
for(i=0; i<clear_ROIs;i++) { 
    array[i] = i;
	}
roiManager("Select", array); 
roiManager("Delete");
run("Close");
selectWindow(name+".tif");
run("Close");


Dialog.create("Analyze another image?");
items = newArray("Open another", "Do another type of analysis", "Exit");
Dialog.addRadioButtonGroup("Analysis done! \n Next Move:", items, 3, 1, "Open another");
Dialog.show;
choice = Dialog.getRadioButton;
if (choice=="Open another") {
	run("__sub_PASCAL_count");

} else {
	if (choice=="Do another type of analysis") {	
		run("PASCAL");
	} 
	if (choice=="Exit") {
		print("\n"+"Thanks for using PASCAL. Bye!");
		}
	}
}


/////////////////////////////

macro "__sub_PASCAL_Save" {

	// Saving data

if (import_type==1) {
	name = getTitle; 
	name = name + ".txt"; 
	saveAs("Measurements"); 
	print("Results saved as: "+name);
	makeRectangle(0, 0, 0, 0);
	run("Revert");
	run("Close");
} else {
	index = lastIndexOf(full_name, "."); 
	if (index!=-1) full_name = substring(full_name, 0, index); 
	name = full_name + ".txt"; 
	saveAs("Measurements", dir+name); 
	print("Results saved as: "+dir+name);
 	}

	// Closing project


clear_ROIs=roiManager("count"); 
array=newArray(clear_ROIs); 
for(i=0; i<clear_ROIs;i++) { 
    array[i] = i;
}
roiManager("Select", array); 
roiManager("Delete");

selectWindow("ROI Manager");
run("Close");


if (import_type==1) {
	run("__sub_PASCAL_Next_Stack");
} else {
	if (import_type==2) {
		run("__sub_PASCAL_Summed_Image");
		}
	if (import_type==3) {
		run("Clear Results");
		run("__sub_PASCAL_Open_Next_Summed");
		}
	}
}

/////////////////////////////

	//open next image stack

macro "__sub_PASCAL_Next_Stack" {

selectWindow("SUM_Stacks");
run("Close");


Dialog.create("Analyze another image?");
items = newArray("Open another", "Change import file type to summed", "Exit");
Dialog.addRadioButtonGroup("Analysis done! Results saves as .txt"+"\n"+"Next Move:", items, 3, 1, "Open another");
Dialog.show;
choice = Dialog.getRadioButton;
if (choice=="Open another") {
	run("__sub_PASCAL_Import");

} else {
	if (choice=="Change import file type to summed") {
		run("Clear Results");	
		run("__sub_PASCAL_Import_Summed");
	} 
	if (choice=="Exit") {
		run("Clear Results");
		selectWindow("Results");
		run("Close");
		print("\n"+"Thanks for using PASCAL. Bye!");
		}
	}
}



/////////////////////////////

	//open next summed image

macro "__sub_PASCAL_Summed_Image" {


run("Close");

Dialog.create("Analyze another image?");
items = newArray("Open another", "Change import file type to non-summed Z-stacks", "Exit");
Dialog.addRadioButtonGroup("Analysis done! Results saves as .txt"+"\n"+"Next Move:", items, 3, 1, "Open another");
Dialog.show;
choice = Dialog.getRadioButton;
if (choice=="Open another") {
	run("__sub_PASCAL_Import_Summed");

} else {
	if (choice=="Change import file type to non-summed Z-stacks") {
		run("Clear Results");	
		run("__sub_PASCAL_Import");
		} 
	if (choice=="Exit") {
		selectWindow("Results");
		run("Close");		
		print("\n"+"Thanks for using PASCAL. Bye!");
		}
	}
}


///////////////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////