//////////////////////////////////////////////////////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////////////////////////
run("Action Bar", "/plugins/ActionBar/SPIM_Shortcuts.ijm");


exit();
//Start of ActionBar

<codeLibrary>


</codeLibrary>


<line>
<button>
label=Open with BIgDataViewer
icon=noicon
arg=<macro>
run("Open XML/HDF5");
</macro>


</line>



<line>
<button>
label=Define MultiView DataSet
icon=noicon
arg=<macro>
run("Define Multi-View Dataset");
</macro>
</line>

<line>
<button>
label=Detect Interest Points For Registration
icon=noicon
arg=<macro>
run("Detect Interest Points For Registration");
</macro>
</line>

<line>
<button>
label=Register Dataset based on Interest Points
icon=noicon
arg=<macro>
run("Register Dataset based on Interest Points");
</macro>
</line>

<line>
<button>
label=Fuse/Deconvolve Dataset
icon=noicon
arg=<macro>
run("Fuse/Deconvolve Dataset");
</macro>
</line>

<line>
<button>
label=Select Bounding Box
icon=noicon
arg=<macro>

getVoxelSize(x,y,z,unit);
id = getImageID();

// Need to get the origin of the Z
imageInfo  = getImageInfo();
imageInfo= split(imageInfo, "\n");

//Search for the origin coordinates
//Array.print(imageInfo);
for(i=0; i<imageInfo.length; i++) {
	//print(imageInfo[i]);
 if (startsWith(imageInfo[i], "Coordinate origin"))  {
 	origin = substring(imageInfo[i], 20, lengthOf( imageInfo[i]));
 	//print(origin);
 	origin = split(origin, ',');

 	print("Z Origin: "+origin[2]);
 }
}

run("Z Project...", "projection=[Max Intensity]");

waitForUser("Make a rectangle and press OK");
getSelectionBounds(x0, y0, width0, height0);
//close();

selectImage(id);
waitForUser("Select Minimum Z");
Stack.getPosition(channel, minZ, frame);
minZ = minZ-origin[2]-1;
waitForUser("Select Maximum Z");
Stack.getPosition(channel, maxZ, frame);
maxZ = maxZ-origin[2]-1;

// Convert with Image Calibration
x1Final = x*x0;
y1Final = y*y0;
x2Final = width0*x + x*x0;
y2Final = height0*y +y*y0;

z1Final = z*minZ;
z2Final = z*maxZ;

//getImage
xmlFile = File.openDialog("Path to XML file");

//showMessage("Final Coordinates: ("+x1Final+", "+y1Final+", "+z1Final+")\n"+"("+x2Final+", "+y2Final+", "+z2Final+")");

run("Fuse/Deconvolve Dataset", "select_xml="+xmlFile+" process_angle=[All angles] process_channel=[All channels] process_illumination=[All illuminations] process_timepoint=[All Timepoints] type_of_image_fusion=[Weighted-average fusion] bounding_box=[Define manually] fused_image=[Display using ImageJ] minimal_x="+x1Final+" minimal_y="+y1Final+" minimal_z="+z1Final+" maximal_x="+x2Final+" maximal_y="+y2Final+" maximal_z="+z2Final+" downsample=2 pixel_type=[32-bit floating point] imglib2_container=ArrayImg process_views_in_paralell=All blend interpolation=[Linear Interpolation]");

</macro>
</line>