// Pad_Image_to_Stack macro by Christophe Leterrier
// 02/10/2011
// Generates a stack from a single image by repeating it

macro Pad_Image_to_Stack {

	setBatchMode(true);
	
	// Retrieves parameters of the input image
	Image_ID=getImageID();
	Image_Title=getTitle();
	Image_Bit=bitDepth();
	getDimensions(Image_Width, Image_Height, channels, slices, frames);

	// Asks the number of slices in the output stack
	Stack_Slices=getNumber("number of slices", 10);
	// Creates the output stack
	newImage(Image_Title+"_Stack", Image_Bit, Image_Width, Image_Height, Stack_Slices);
	Stack_ID=getImageID();
	
	// Copies the input image
	selectImage(Image_ID);
	run("Select All");
	run("Select None");
	run("Copy");

	// Selects the output stack
	selectImage(Stack_ID);
	// Loops on all output stack slices and paste the input image on each slice
	for (i=0; i<Stack_Slices; i++) {
		setSlice(i+1);
		run("Paste");
	}
	
	run("Select None");
		
	// Set the display contrast
	resetMinAndMax;
	
	setBatchMode("exit and display");
	showStatus("Pad_Image_to_Stack finished");
}