// Extract_LIF macro by Christophe Leterrier
// 19-10-2011
//
// Takes a folder of raw Leica LIF images and extracts them to .tif images/stacks, separating channels (C=X).
// The extracted images/stacks are located in a folder defined in the menu.
// Other options : reset spatial scales, reads ROIs stored in Axiovision, close all images at the end.
//
// Folder Structure:
//
// •Experiment folder
// |–•Extracted (created from raw images by this macro)
//
// Updates:
// 14-11-2010: Changed the save options, with two options for saving in the 'Data Edit' folder.
//             these options depend on the folder structure which is specified by SOURCE_DIR and DEST_DIR folder names

macro "Extract_LIF" {
	// Default values for the Options Panel
	RESET_SCALE_DEF=true;
	CATCH_ROIS_DEF=false;
	CLOSE_IMAGES_DEF=true;
	SAVE_DEF="In a folder next to the source folder";

	// Defaults raw and processed image folders for the 'Data Edit' saving modes
	// These folders MUST BE 'brother folders' next to each other in the path for images
	// because the switch from one to another is relative.
	// This allows to work on any computer regardless of the absolute path
	SOURCE_DIR = "Data Raw";
	DEST_DIR = "Data Edit";

	// Get the folder name
	INPUT_DIR=getDirectory("Select a directory");

	print("\n\n\n*** Extract_LIF Log ***");
	print("INPUT_DIR :"+INPUT_DIR);

	// Initialize choices variables
	SAVE_ARRAY = newArray("'Extracted' in the 'Data Edit' folder", "Same folder in the 'Data Edit' folder", "In the source folder", "In a subfolder of the source folder", "In a folder next to the source folder", "In a custom folder");

	// Creation of the dialog box
	Dialog.create("Extractor Options");
	Dialog.addCheckbox("Reset Spatial Scale", RESET_SCALE_DEF);
	Dialog.addCheckbox("Catch ROIs", CATCH_ROIS_DEF);
	Dialog.addCheckbox("Close Images", CLOSE_IMAGES_DEF);
	Dialog.addChoice("Save Images", SAVE_ARRAY, SAVE_DEF);
	Dialog.show();

	// Feeding variables from dialog choices
	RESET_SCALE=Dialog.getCheckbox();
	CATCH_ROIS=Dialog.getCheckbox();
	CLOSE_IMAGES=Dialog.getCheckbox();
	SAVE_TYPE=Dialog.getChoice();


	// Get all file names
	ALL_NAMES=getFileList(INPUT_DIR);
	Array.sort(ALL_NAMES);
	ALL_EXT=newArray(ALL_NAMES.length);
	// Create extensions array
	for (i=0; i<ALL_NAMES.length; i++) {
	//	print(ALL_NAMES[i]);
		LENGTH=lengthOf(ALL_NAMES[i]);
		ALL_EXT[i]=substring(ALL_NAMES[i],LENGTH-4,LENGTH);
	}

	setBatchMode(true);

	// Create the output folder
	OUTPUT_DIR="Void";

	if (SAVE_TYPE=="'Extracted' in the 'Data Edit' folder") {
		OUTPUT_DIR = replace(INPUT_DIR, SOURCE_DIR, DEST_DIR);
		DIR_STRUCT = split(OUTPUT_DIR, File.separator);
		DEST_ROOT=File.separator;
		for (i = 0; i < DIR_STRUCT.length; i++) {
			DEST_ROOT += DIR_STRUCT[i] + File.separator;
			if (File.isDirectory(DEST_ROOT) == false) {
				File.makeDirectory(DEST_ROOT);
			}
		}
		OUTPUT_DIR = DEST_ROOT+"Extracted"+File.separator;
		if (File.isDirectory(OUTPUT_DIR) == false) {
			File.makeDirectory(OUTPUT_DIR);
		}
	}

	if (SAVE_TYPE=="Same folder in the 'Data Edit' folder") {
		OUTPUT_DIR = replace(INPUT_DIR, SOURCE_DIR, DEST_DIR);
		DIR_STRUCT = split(OUTPUT_DIR, File.separator);
		DEST_ROOT=File.separator;
		for (i = 0; i< DIR_STRUCT.length - 1; i++) {
			DEST_ROOT += DIR_STRUCT[i] + File.separator;
			if (File.isDirectory(DEST_ROOT) == false) {
				File.makeDirectory(DEST_ROOT);
			}
		}
		OUTPUT_DIR = DEST_ROOT+DIR_STRUCT[DIR_STRUCT.length-1]+File.separator;
		if (File.isDirectory(OUTPUT_DIR) == false) {
			File.makeDirectory(OUTPUT_DIR);
		}
	}

	if (SAVE_TYPE=="In the source folder") {
		OUTPUT_DIR=INPUT_DIR;
	}

	if (SAVE_TYPE=="In a subfolder of the source folder") {
		OUTPUT_DIR=INPUT_DIR+"Extracted"+File.separator;
		if (File.isDirectory(OUTPUT_DIR) == false) {
			File.makeDirectory(OUTPUT_DIR);
		}
	}

	if (SAVE_TYPE=="In a folder next to the source folder") {
		OUTPUT_DIR=File.getParent(INPUT_DIR);
		OUTPUT_NAME=File.getName(INPUT_DIR);
		OUTPUT_DIR=OUTPUT_DIR+File.separator+OUTPUT_NAME+" Extracted"+File.separator;
		if (File.isDirectory(OUTPUT_DIR) == false) {
			File.makeDirectory(OUTPUT_DIR);
		}
	}

	if (SAVE_TYPE=="In a custom folder") {
		OUTPUT_DIR=getDirectory("Choose the save folder");
	}

	OUTPUT_PARENT_DIR=File.getParent(OUTPUT_DIR);

	print("OUTPUT_DIR: "+OUTPUT_DIR);
	print("OUTPUT_PARENT_DIR: "+OUTPUT_PARENT_DIR);

	// Loop on all .lif extensions
	for (n=0; n<ALL_EXT.length; n++) {
		if (ALL_EXT[n]==".lif") {

			// Get the file path
			FILE_PATH=INPUT_DIR+ALL_NAMES[n];

			// Store components of the file name
			FILE_NAME=File.getName(FILE_PATH);
			FILE_PATH_LENGTH=lengthOf(FILE_PATH);
			FILE_NAME_LENGTH=lengthOf(FILE_NAME);
			FILE_DIR=substring(FILE_PATH,0,FILE_PATH_LENGTH-FILE_NAME_LENGTH);
			FILE_EXT=substring(FILE_NAME,FILE_NAME_LENGTH-4,FILE_NAME_LENGTH);
			FILE_SHORTNAME=substring(FILE_NAME,0,FILE_NAME_LENGTH-4);

			print("");
			print("INPUT_PATH:", FILE_PATH);
	//		print("FILE_NAME:", FILE_NAME);
	//		print("FILE_DIR:", FILE_DIR);
	//		print("FILE_EXT:", FILE_EXT);
	//		print("FILE_SHORTNAME:", FILE_SHORTNAME);

			// Start BioFormats and get series number in file.
			print("Setting Bio-Formats Id...");
			run("Bio-Formats Macro Extensions");
			Ext.setGroupFiles("false");
			Ext.setId(FILE_PATH);
			Ext.getSeriesCount(SERIES_COUNT);
			SERIES_NAMES=newArray(SERIES_COUNT);

			for (s=0; s<SERIES_COUNT; s++) {

				// Get serie name and channels count
				Ext.setSeries(s);
				Ext.getEffectiveSizeC(CHANNEL_COUNT);
				SERIES_NAMES[s]="";
				Ext.getSeriesName(SERIES_NAMES[s]);

				TEMP_NAME=toLowerCase(SERIES_NAMES[s]);

				print("SERIES_NAMES["+s+"]: "+ SERIES_NAMES[s] + " (TEMP_NAME: " + TEMP_NAME +")");

				// Import the serie (split channels)
				showStatus("launching Bio-Formats Importer");
				print("Launching Bio-Formats Importer...");

				// 07-09-2011 added display_rois (added to ROI Manager)
				// 27-09-2011 made dispalys_rois optionnal to speed things up
				if (CATCH_ROIS==true) {
					DISPLAY=" display_rois";
					roiManager("reset");
				}
				else {
					DISPLAY="";
				}

				run("Bio-Formats Importer", "open=["+ FILE_PATH + "] " + "split_channels view=[Standard ImageJ]" + " stack_order=Default " + "series_"+d2s(s+1,0)+DISPLAY);
				print("Bio-Formats Importer launched");



				// Loop on each channel (each opened window)
				for(j=0; j<CHANNEL_COUNT; j++) {

					// Construct stack name
					TEMP_CHANNEL=d2s(j,0);
					// stack has series Name in title only if more than one serie
					if(SERIES_COUNT==1) {
						SOURCE_WINDOW_NAME=FILE_NAME+ " - C="+TEMP_CHANNEL;
					}
					else {
					SOURCE_WINDOW_NAME=FILE_NAME+" - "+SERIES_NAMES[s]+" - C="+TEMP_CHANNEL;
					}

					//Select source image and filter if asked
					selectWindow(SOURCE_WINDOW_NAME);

					// to get the display contrast right (does not change pixel values, just display)
					resetMinAndMax;

					// Reset spatial scale of images if checked
					if (RESET_SCALE==true) {
						run("Set Scale...", "distance=0 known=1 pixel=1 unit=pixel");
					}

					// 07-09-2011 Put ROIs in overlay
					if (roiManager("count")>0) {
						run("From ROI Manager");
					}

					// rename image according to processing
					// 07-09-2011 removed multi-channel condition for TYPE
					NEW_WINDOW_NAME=FILE_SHORTNAME+"-"+SERIES_NAMES[s]+"-C="+TEMP_CHANNEL;
					rename(NEW_WINDOW_NAME);

					// Create output file path and save the output image
					OUTPUT_PATH=OUTPUT_DIR+NEW_WINDOW_NAME+".tif";
					save(OUTPUT_PATH);
					print("OUTPUT_PATH: "+OUTPUT_PATH);

					// Close output image if checked
					if (CLOSE_IMAGES==true) {
						close();
					}

				}	// end of FOR loop on channels
			} //end of FOR loop on series
		}// end of IF loop on tif extensions
	}// end of FOR loop on all files

	setBatchMode("exit and display");
	print("");
	print("*** Extract_LIF end ***");
	showStatus("Extract LIF finished");
//	exec("open", OUTPUT_DIR);
}