// This macro displays, as a montage, all the LUTs a given folder
// C Leterrier 12/06/2021
// Adapted from ImageJ macro "Display LUTs"

macro "Browse LUTs" {
	saveSettings();
	inDir = getDirectory("Choose diectrory containing LUTs");
	listraw = getFileList(inDir);
	list = newArray(0);
	for (i = 0; i<listraw.length; i++) {
		if (endsWith(listraw[i], ".lut") == true) list = Array.concat(list, listraw[i]);
	}
	setBatchMode(true);
	newImage("ramp", "8-bit Ramp", 256, 32, 1);
	newImage("luts", "RGB White", 256, 48, 1);
	count = 0;
	setForegroundColor(255, 255, 255);
	setBackgroundColor(255, 255, 255);
	setFont("SansSerif", 12,"antialiased");
	for (i=0; i<list.length; i++) {
	    selectWindow("ramp");
	    open(inDir + list[i]);
	    run("Select All");
	    run("Copy");
	    selectWindow("luts");
	    makeRectangle(0, 0, 256, 32);
	    run("Paste");
	    setJustification("center");
	    setColor(0, 0, 0);
	    drawString(substring(list[i], 0, lengthOf(list[i])-4),128, 48);
	    run("Add Slice");
	    run("Select All");
	    run("Clear", "slice");
	    count++;
	}
	run("Delete Slice");
	// rows = floor(count/4);
	// if (rows<count/4) rows++;
	run("Canvas Size...", "width=258 height=50 position=Center");
	run("Make Montage...", "columns=1 rows="+list.length 
	+" scale=1 first=1 last="+count+" increment=1 border=0 use");
	rename("Lookup Tables");
	setBatchMode(false);
	restoreSettings();
}