macro "Apply LUTs Montage" {

	oridir = File.getDefaultDir;
	rootdir = getDir("imagej");
	startdir = rootdir + "scripts" + File.separator + "LUTs" + File.separator + "___Grays_.ijm";
	File.setDefaultDir(startdir);
	lutdir = getDir("Choose folder");
	File.setDefaultDir(oridir);
	
	displayNCLUTs(lutdir);
	
	//chouette moyen d'installer le tool sans virer les macros installées avant :
	eval("script", "new Packages.ij.plugin.MacroInstaller().installTool(IJ.getDirectory(\"imagej\")+\"/scripts/LUTs/NCLUTs Tool.ijm\");");

}

function displayNCLUTs(directory) {
	//adapted from https://imagej.nih.gov/ij/macros/Show_All_LUTs.txt
	//make LUTs montage from the NeuroCyto LUTs script folder
	//Kevin Terretaz 2022
	saveSettings();
	list = getFileList(directory);
	propertyList = "";
	setBatchMode(true);
	newImage("ramp", "8-bit Ramp", 256, 32, 1);
	newImage("luts", "RGB White", 256, 48, 1);
	count = 0;
	setForegroundColor(255, 255, 255);
	setBackgroundColor(255, 255, 255);
	for (i=0; i<list.length; i++) {
		if (endsWith(File.getName(directory+list[i]), "_.ijm") && !File.isDirectory(directory+list[i])){
	      selectWindow("ramp");
	      script = File.openAsString(directory+list[i]);
	      eval(script);
	      propertyList += script;
	      run("Copy");
	      selectWindow("luts");
	      makeRectangle(0, 0, 256, 32);
	      run("Paste");
	      setJustification("center");
	      setColor(0,0,0);
	      setFont("SansSerif", 11, "antialiased");
	      name = list[i];
		  name = substring(name, 0, name.length-5);
	      drawString(name, 128, 48);
	      run("Add Slice");
	      run("Select All");
	      run("Clear", "slice");
	      count++;
		}
	}
	run("Delete Slice");
	rows = floor(count/4);
	if (rows<count/4) rows++;
	run("Canvas Size...", "width=258 height=50 position=Center");
	setBackgroundColor(0, 0, 0);
	run("Make Montage...", "columns=4 rows="+rows+" scale=1 first=1 last="+count+" increment=1 border=0 use");
	rename("Lookup Tables");
	Property.set("PropertyList", propertyList);
	setBatchMode(false);
	restoreSettings();
}