//SAMA
version=0.97;
//Copyright (C) 2015 Maël Montévil and Tessie Paulose 

//    This program is free software: you can redistribute it and/or modify
//    it under the terms of the GNU General Public License as published by
//    the Free Software Foundation, either version 3 of the License, or
//    (at your option) any later version.

//    This program is distributed in the hope that it will be useful,
//    but WITHOUT ANY WARRANTY; without even the implied warranty of
//    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//    GNU General Public License for more details.

//    You should have received a copy of the GNU General Public License
//    along with this program.  If not, see <http://www.gnu.org/licenses/>.


chosendir = getDirectory("Choose the original images Directory");
list = getFileList(chosendir);
dir=File.getParent(chosendir)+"/";
Rdatadir =dir+"SAMA-Image data/";
run("Clear Results");
plate="Experiment1";
well="Replicate1";
addTreatment=true;
Treatments = newArray(0); 
Treatmentsb = newArray(0); 
manual=false;
while(addTreatment){
  Dialog.create("Add a new experimental parameter");
  Dialog.addMessage("WARNING: this process will overwrite your former conditions.csv file if any.");
  Dialog.addMessage("Add a new experimental parameter.");
  Dialog.addString("Name of the experimental parameter","Condition1", 20);
  Dialog.addCheckbox("Add another experimental parameter?", false);
  Dialog.addCheckbox("Input the conditions for each stack here (tedious for large datasets)?", manual);
  Dialog.addMessage("Alternatively you can complete consitions.csv with Excel or Openoffice.");
  Dialog.show();
  Treatments = Array.concat(Treatments,Dialog.getString());	
  Treatmentsb = Array.concat(Treatmentsb,"");	
  addTreatment=Dialog.getCheckbox();
  manual=Dialog.getCheckbox();
}

for (i=0; i<list.length; i++) {
  
  setResult("name", nResults, substring(list[i], 0, 7));
  if (manual)
  {
    Dialog.create("Specify condition for "+list[i]);
    Dialog.addMessage("Specify condition for "+list[i]);
    Dialog.addString("Experiment",plate, 10);
    Dialog.addString("Replicate",well, 10);
    for (j=0; j<Treatments.length; j++) {
      Dialog.addString(Treatments[j],Treatmentsb[j], 20);
    }
    Dialog.show();
    plate = Dialog.getString();	
    well = Dialog.getString();	
    setResult("Plate", nResults-1, plate);
    setResult("Well", nResults-1, well);	
    for (j=0; j<Treatments.length; j++) {
      treat= Dialog.getString();
      setResult(Treatments[j], nResults-1,treat);
      Treatmentsb[j]=treat;
    }}else{
      setResult("Plate", nResults-1, plate);
      setResult("Well", nResults-1, well);		
      for (j=0; j<Treatments.length; j++) {
	setResult(Treatments[j], nResults-1,"");
	Treatmentsb[j]="";
      }
    }
    
    
}
setOption("ShowRowNumbers",false);
saveAs("Results", Rdatadir +"conditions.csv");