//SAMA
version=0.97;
//Copyright (C) 2015 Maël Montévil and Tessie Paulose 

//    This program is free software: you can redistribute it and/or modify
//    it under the terms of the GNU General Public License as published by
//    the Free Software Foundation, either version 3 of the License, or
//    (at your option) any later version.

//    This program is distributed in the hope that it will be useful,
//    but WITHOUT ANY WARRANTY; without even the implied warranty of
//    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//    GNU General Public License for more details.

//    You should have received a copy of the GNU General Public License
//    along with this program.  If not, see <http://www.gnu.org/licenses/>.


items=newArray("None","Puredenoise","Bilateral filter");

//interface
dirsource = getDirectory("Choose Source Directory");
dirout = getDirectory("Choose Destination Directory");

Dialog.create("Preprocessing options");
Dialog.addChoice("Additional filtering", items,"None");
Dialog.addNumber("Value of the background", 0);
Dialog.show();
mode = Dialog.getChoice();
sub = Dialog.getNumber();

//batch process the files
list = getFileList(dirsource);

setBatchMode(true);
for (j=0; j<list.length; j++) {
  showProgress(j+1, list.length);
  open(dirsource+list[j]);
  run("Enhance Contrast...", "saturated=0.001 normalize process_all use");
  run("Subtract...", "value="+sub+" stack");
  if(mode=="Puredenoise"){
    run("PureDenoise ...", "parameters='3 4' estimation='Auto Global' ");
  }
  if(mode=="Bilateral filter"){
    run("Bilateral Filter", "spatial=2 range=50");
  }
  run("Enhance Contrast...", "saturated=0.001 normalize process_all use");
  saveAs("TIFF", dirout+list[j]);
  close();
}
setBatchMode(false);