// @int(label = "Number of Rows:", value=3) numRow
// @int(label = "Number of Columns:", value=3) numCol
// @double(label = "Image scaling factor:", value=0.5) numScale
// @double(label = "Image Width (inches):", value=8.5, description="This is the width in inches that you wish to use for you horizontal field of view.") hFOV 
// @String(label = "Close stack after?", choices={"Yes", "No"}, style="radioButtonHorizontal") closeStack
// @String(label = "Edit stack order?", choices={"Yes", "No"}, style="radioButtonHorizontal") editStack
// @String(Label = "Include filename/label?", choices={"filename", "label", "none"}, style="radioButtonHorizontal", description="Note: This will not remove names from a stack that already has names..") fileName
// @String(Label = "Include Border?", choices={"Yes", "No"}, style="radioButtonHorizontal") useBorder

// Check if a stack is already open, if not, convert the open windows into a stack.
if (nSlices<2) {
	run("Images to Stack", "name=Stack title=[] use"); 
}

// If you want to edit the stack order.
if (editStack=="Yes") {
	run("Stack Sorter");
	waitForUser;
}

// Need the identifyer of the stack
stackID=getImageID;

// Some image types didn't work so this converts those types to a type that does.
stackType = ""+bitDepth;
if (stackType=="24") 
   	stackType = "RGB";
else if (stackType=="16" || stackType=="32") 
   	run("8-bit");
   	stackType = ""+bitDepth;

// Reset scale according to user's preferences.
scaleStack(numScale);

// Writes filenames on images as inset per user's preferences.
if (fileName=="filename") {
	filenameOnStack(stackID);
}
if (fileName=="label") {
	labelOnStack(stackID);
}

// Make the monage using Mak's setup.
maksMontage(numRow,numCol, stackID);
montageID=getImageID;

// Remove the montage border for peer review journal figures.
if (useBorder=="No") {
	cropMontage(stackID, montageID, numCol);
}

// Set the HFOV of the montage so it will achieve a certain DPI.
setMontageFOV(hFOV);

// If the user doesn't need the stack anymore: closes it.
if (closeStack=="Yes") {
	selectImage(stackID);
	close();
}

/*
 *************************
 * * * * FUNCTIONS * * * *
 *************************
 */

// Creates a 2D montage of the images in the stack with spaces and a border.
function maksMontage(rows, columns, stackID) {
	setBatchMode(true);
    stackWidth=getWidth; 
    stackHeight=getHeight;
    stackType = ""+bitDepth;
    montageSpaces=floor(stackHeight*1/50);
    montageBorder=columns*floor(stackHeight*1/5);
    newImage("montage", stackType+" black", columns*(getWidth+montageSpaces)+2*montageBorder-montageSpaces, rows*(getHeight+montageSpaces)+2*montageBorder-montageSpaces, 1);
    setColor(255, 255, 255); fill;
    montageWidth=(getWidth-2*montageBorder)/columns; 
    montageHeight=(getHeight-2*montageBorder)/rows;
    montageID=getImageID;
    selectImage(stackID);
    for (i=0; i<rows*columns; i++) {
        selectImage(stackID);
        if (i+1<=nSlices) {
        	setSlice(i+1);
       		run("Select All");
        	run("Copy");
        	selectImage(montageID);       
        	makeRectangle((i%columns)*(stackWidth+montageSpaces)+montageBorder, floor(i/columns)*(stackHeight+montageSpaces)+montageBorder, stackWidth, stackHeight);
        	run("Paste");
        } else {
        	selectImage(montageID);       
        	makeRectangle((i%columns)*(stackWidth+montageSpaces)+montageBorder, floor(i/columns)*(stackHeight+montageSpaces)+montageBorder, stackWidth, stackHeight);
        	setColor(255, 255, 255); 
    		fill;	
        }
    }
    resetMinAndMax();
    run("Select None");
    setBatchMode(false); // display the montage
}

// Labels each image with the images own filename.
function filenameOnStack(stackID) {
	setBatchMode(true);
	selectImage(stackID);
	for (i=0; i<nSlices; i++) {
		selectImage(stackID);
		setSlice(i+1);
		fileName=getInfo("slice.label");
		setColor("black");
		setFont("Serif",floor(getHeight/20));
		x=floor(getWidth/32); y=floor(getHeight/12);
		setJustification("left");
		drawString(fileName, x, y, "white");
	}
	setBatchMode(false);
}

// Labels each image with a letter.
function labelOnStack(stackID) {
	setBatchMode(true);
	selectImage(stackID);
	label=newArray("(a)","(b)","(c)","(d)","(e)","(f)","(g)","(h)","(i)","(j)","(k)","(l)","(m)","(n)","(o)","(p)","(q)","(r)","(s)","(t)","(u)","(v)","(w)","(x)","(y)","(z)","(aa)","(bb)","(cc)","(dd)","(ee)","(ff)","(gg)","(hh)","(ii)","(jj)","(kk)","(ll)","(mm)","(nn)","(oo)","(pp)","(qq)","(rr)","(ss)","(tt)","(uu)","(vv)","(ww)","(xx)","(yy)","(zz)","(aaa)","(bbb)","(ccc)","(ddd)","(eee)","(fff)","(ggg)","(hhh)","(iii)","(jjj)","(kkk)","(lll)","(mmm)","(nnn)","(ooo)","(ppp)","(qqq)","(rrr)","(sss)","(ttt)","(uuu)","(vvv)","(www)","(xxx)","(yyy)","(zzz)");
	for (i=0; i<nSlices; i++) {
		selectImage(stackID);
		setSlice(i+1);
		fileName=label[i];
		setColor("black");
		setFont("Serif",floor(getHeight/16), "bold");
		x=floor(getWidth/32); y=floor(getHeight/9);
		setJustification("left");
		drawString(fileName, x, y, "white");
	}
	setBatchMode(false);
}

// Sets the horizontal FOV of the window named 'montage' to a specified length in inches.
function setMontageFOV(length) {
	setBatchMode(true);
	selectWindow("montage");
	imageWidth = getWidth;
	run("Set Scale...", "distance="+imageWidth+" known="+length+" pixel=1.0 unit=inch");
	setBatchMode(false);
}

// Resizes the images within the stack by a factor entered by the user.
function scaleStack(scaleFactor) {
	setBatchMode(true);
	stackID=getImageID;
	selectImage(stackID);
	newWidth=floor(scaleFactor*getWidth); newHeight=floor(scaleFactor*getHeight);
	run("Size...", "width="+newWidth+" height="+newHeight+" depth="+nSlices+" constrain average interpolation=Bilinear");
	setBatchMode(false);
}

// This will crop the border off of the montage.
function cropMontage(stackID, montageID, columns) {
	setBatchMode(true);
	selectImage(stackID);
	stackHeight=getHeight;
	selectImage(montageID);
	montageWidth=getWidth;
	montageHeight=getHeight;
	montageBorder=columns*floor(stackHeight*1/5);
	rectanglePosition=montageBorder;
	rectangleX=montageWidth-2*montageBorder;
	rectangleY=montageHeight-2*montageBorder;
	makeRectangle(rectanglePosition, rectanglePosition, rectangleX, rectangleY);
	run("Crop");
	setBatchMode(false);
}