// @int(label = "Number of Rows:", value=3) numRow
// @int(label = "Number of Columns:", value=3) numCol
// @double(label = "Image scaling factor:", value=0.5) numScale
// @double(label = "Horizontal FOV (inch):", value=8.5, description="This is the width in inches that you wish to use for you horizontal field of view.") hFOV 
// @String(label = "Close stack after?", choices={"Yes", "No"}, style="radioButtonHorizontal") closeStack
// @String(label = "Edit stack order?", choices={"Yes", "No"}, style="radioButtonHorizontal") editStack
// @String(Label = "Include filename?", choices={"Yes", "No"}, style="radioButtonHorizontal", description="Note: This will not remove names from a stack that already has names..") fileName
// @String(Label = "Include Border?", choices={"Yes", "No"}, style="radioButtonHorizontal") useBorder

// Check if a stack is already open, if not, convert the open windows into a stack.
if (nSlices<2) {
	run("Images to Stack", "name=Stack title=[] use"); 
	if (editStack=="Yes") {
		run("Stack Sorter");
		waitForUser;
	}
}

// Need the identifyer of the stack
stackID=getImageID;

// Check for stack index out of range error:
if (nSlices<numRow*numCol)
	exit("Error: The number of images in the montage must be \nless than or equal to the number of images in the stack \n(i.e. rows*columns =< images in stack).");

// Some image types didn't work so this converts those types to a type that does.
stackType = ""+bitDepth;
if (stackType=="24") 
   	stackType = "RGB";
else if (stackType=="16" || stackType=="32") 
   	run("8-bit");
   	stackType = ""+bitDepth;

// Reset scale according to user's preferences.
scaleStack(numScale);

// Writes filenames on images as inset per user's preferences.
if (fileName=="Yes") {
	filenameOnStack(stackID);
}

// Make the monage using Mak's setup.
maksMontage(numRow,numCol, stackID);
montageID=getImageID;

// Remove the montage border for peer review journal figures.
if (useBorder=="No") {
	cropMontage(stackID, montageID);
}

// Set the HFOV of the montage so it will achieve a certain DPI.
setMontageFOV(hFOV);

// If the user doesn't need the stack anymore: closes it.
if (closeStack=="Yes") {
	selectImage(stackID);
	close();
}

/*
*************************
 *      FUNCTIONS
*************************
 */

// Creates a 2D montage of the images in the stack with spaces and a border.
function maksMontage(rows, columns, stackID) {
	setBatchMode(true);
    stackWidth=getWidth; 
    stackHeight=getHeight;
    stackType = ""+bitDepth;
    montageSpaces=floor(stackHeight*1/50);
    montageBorder=10*montageSpaces;
    newImage("montage", stackType+" black", columns*(getWidth+montageSpaces)+2*montageBorder, rows*(getHeight+montageSpaces)+2*montageBorder, 1);
    setColor(255, 255, 255); fill;
    montageWidth=(getWidth-2*montageBorder)/columns; 
    montageHeight=(getHeight-2*montageBorder)/rows;
    montageID=getImageID;
    selectImage(stackID);
    for (i=0; i<rows*columns; i++) {
        selectImage(stackID);
        setSlice(i+1);
        run("Select All");
        run("Copy");
        selectImage(montageID);       
        makeRectangle((i%columns)*montageWidth+montageBorder, floor(i/columns)*montageHeight+montageBorder, stackWidth, stackHeight);
        run("Paste");
    }
    resetMinAndMax();
    setBatchMode(false); // display the montage
}

// Writes the image filename to each stack slice.
function filenameOnStack(stackID) {
	setBatchMode(true);
	selectImage(stackID);
	slices=nSlices;
	for (i=0; i<slices; i++) {
		selectImage(stackID);
		setSlice(i+1);
		fileName=getInfo("slice.label");
		setColor("black");
		setFont("Serif",floor(getHeight/20));
		x=floor(getWidth/32); y=floor(getHeight/12);
		setJustification("left");
		drawString(fileName, x, y, "white");
	}
	setBatchMode(false);
}

// Sets the horizontal FOV of the window named 'montage' to a specified length in inches.
function setMontageFOV(length) {
	setBatchMode(true);
	selectWindow("montage");
	imageWidth = getWidth;
	run("Set Scale...", "distance="+imageWidth+" known="+length+" pixel=1.0 unit=inch");
	setBatchMode(false);
}

// Resizes the images within the stack by a factor entered by the user.
function scaleStack(scaleFactor) {
	setBatchMode(true);
	stackID=getImageID;
	selectImage(stackID);
	newWidth=floor(scaleFactor*getWidth); newHeight=floor(scaleFactor*getHeight);
	run("Size...", "width="+newWidth+" height="+newHeight+" depth="+nSlices+" constrain average interpolation=Bilinear");
	setBatchMode(false);
}

function cropMontage(stackID, montageID) {
	setBatchMode(true);
	selectImage(stackID);
	stackHeight=getHeight;
	selectImage(montageID);
	montageWidth=getWidth;
	montageHeight=getHeight;
	montageBorder=floor(stackHeight*1/5);
	rectanglePosition=montageBorder;
	rectangleX=montageWidth-2*montageBorder;
	rectangleY=montageHeight-2*montageBorder;
	makeRectangle(rectanglePosition, rectanglePosition, rectangleX, rectangleY);
	run("Crop");
	setBatchMode(false);
}