/*
 * This plugin extracts the image metadata for all the DM3 image files in a directory 
 * and saves the metadata to a text file.
 */

// Choose the directory that contains the DM3 files from which you need the metadata.
directory = getDirectory("Choose a Directory");
setBatchMode(true);
count = 0;

// This is a list of the filenames in the directory.
filenames = getFileList(directory);

// Loop over the list of filenames and find the DM3 files.
for (i=0; i<filenames.length; i++) {
	if (endsWith(filenames[i], ".dm3")) {
		// Open each image, grab the metadata, save a text file, and close.
		open(directory + filenames[i]);
		imageFile = getImageID();
		grabMetadata();
		saveAs("text", directory + filenames[i]);
		close("Info for " + filenames[i]);
		selectImage(imageFile);
		// To also save the DM3 file as tiff:
		//saveAs("tiff", directory + filenames[i]);
		//close();
		count++;
	}
}

print("Number of DM3 files processed: " + count );

// FUNCTIONS

// Extracts the metadata from the image and dumps it in a text file.
function grabMetadata() {
	run("Show Info...");
}