// @int(label = "Min Diffraction spot size (pix^2)", value=7, description="Minimum number of pixels that consitutes a diffraction spot.") minSize
// @String(label = "Beamstop Status:", choices={"Retracted", "Inserted"}, style="radioButtonHorizontal", description="If a beamstop was used, the center of the pattern is calculated differently than if no beamstop was used.") beamStopStatus

// INITIALIZATION
run("Duplicate...", " ");
run("8-bit");
run("Clear Results");
resetThreshold(); 
setAutoThreshold("Default dark");
setThreshold(130, 255);
//run("Threshold...");

// ADJUSTING THE THRESHOLDING LEVELS
if (getBoolean("Did Auto Thresholding work?")==false) {
	Dialog.create("Adjust Threshold");
	Dialog.addSlider("Lower:", 0, 255, 130);
	Dialog.addSlider("Upper:", 0, 255, 255);
	Dialog.show();
	Lower = Dialog.getNumber();
	Upper = Dialog.getNumber();
	setThreshold(Lower, Upper);
	while (getBoolean("Click \"Yes\" when Thresholding is OK.")==false) {
		Dialog.create("Adjust Threshold");
		Dialog.addSlider("Lower:", 0, 255, Lower);
		Dialog.addSlider("Upper:", 0, 255, Upper);
		Dialog.show();
		Lower = Dialog.getNumber();
		Upper = Dialog.getNumber();
		setThreshold(Lower, Upper);
	}
}
else {
	
}

// TAKE MEASUREMENTS
run("Set Measurements...", "area centroid redirect=None decimal=4");
run("Analyze Particles...", "size=" + minSize + "-Infinity pixel circularity=0.0-1.00 show=[Overlay Masks] display exclude include");
run("Labels...", "color=red font=28 show"); 

// BEAMSTOP STATUS
if (beamStopStatus == "Retracted") {
	Dialog.create("Direct Beam Center");
	Dialog.addMessage("Enter the label that corre-\nsponds to the direct beam.\n ");
	Dialog.addNumber("             (000):", 10);
	Dialog.show();
	
	nextRow = Dialog.getNumber();
	dbRow = nextRow-1;
	
	directBeamX = getResult("X", dbRow);
	directBeamY = getResult("Y", dbRow);

}
else if (beamStopStatus == "Inserted") {
	Dialog.create("Direct Beam Center");
	Dialog.addMessage("Enter two spots that are mirrored about the direct \nbeam, and are equidistant from its center.\n ");
	Dialog.addNumber("                    Spot 1:", 10);
	Dialog.addNumber("                    Spot 2:", 30);
	Dialog.addMessage("");
	Dialog.addNumber("                  No. of Artifacts:", 2);
	Dialog.addMessage("");
	Dialog.show();
	
	nextRowSpotOne = Dialog.getNumber();
	nextRowSpotTwo = Dialog.getNumber();
	ignoreSpots = Dialog.getNumber();
	rowSpotOne = nextRowSpotOne-1;
	rowSpotTwo = nextRowSpotTwo-1;

	spotOneX = getResult("X", rowSpotOne);
	spotOneY = getResult("Y", rowSpotOne);
	spotTwoX = getResult("X", rowSpotTwo);
	spotTwoY = getResult("Y", rowSpotTwo);

//	Taking the average makes the order entered irrelevant
	directBeamX = (spotOneX+spotTwoX)/2;	
	directBeamY = (spotOneY+spotTwoY)/2;
//	print(directBeamX,directBeamY);
}
else {
	print("Warning! BeamStop stauts needs to be selected.");
}

// CALCULATIONS
label = newArray();
area = newArray();
xPos = newArray();
yPos = newArray();
G = newArray();
dSpace = newArray();

for (row=0; row<nResults; row++) {
	indexRow = row+1;
	a = getResult("Area",row);
	spotX = getResult("X",row);
	spotY = getResult("Y",row);
	g = sqrt((spotX-directBeamX)*(spotX-directBeamX)+(spotY-directBeamY)*(spotY-directBeamY));	// Thanks Pythagoras!
	d = 10/g;
	G = Array.concat(G, g);
	dSpace = Array.concat(dSpace, d);
	label = Array.concat(label, indexRow);
	area = Array.concat(area, a);
	xPos = Array.concat(xPos, spotX);
	yPos = Array.concat(yPos, spotY);
	setResult("G (1/nm)", row, g);
	setResult("d (A)", row, d);
}
updateResults();

// How much to trim dSpace for the plot later...
if (beamStopStatus == "Retracted") {
	cut = nResults-1;
	}
	else if (beamStopStatus == "Inserted") {
	cut = nResults-ignoreSpots;
	}
	else {
	print("Forgot to enter number of spot to ignore");
}

// TRIMMING dSpace Array for plot
dSpace = Array.sort(dSpace);
dSpace = Array.trim(dSpace, cut);
dSpaceAve = aveByFamily(dSpace);
dSpaceAve2 = sortDescending(dSpaceAve);

// PLOTTING dSpace TO HELP GROUP PLANES BY FAMILY
Plot.create("", "Measured Spots", "Plane Spacings");
Plot.setColor("blue", "blue");
Plot.add("circle", dSpace);
Plot.setColor("red", "red");
Plot.add("boxes", dSpaceAve);

// Create my text window...
printToText("d (A) = ", dSpaceAve2);

// FUNCTIONS
// This will average the measurements from a family of planes and return a single array with the average values
function aveByFamily(d0) {
	d1=newArray();
	d2=newArray();
	for (i=0; i<d0.length; i++) {
		d1=Array.concat(d1, d0[i]);
		dDiff=d0[i+1]-d0[i];
		if (dDiff>=0.05) {
			Array.getStatistics(d1, min, max, mean, std);
			d2=Array.concat(d2, mean);
			d1=newArray();
		}
		if (i==d0.length-2) {
			last=d0.length-1;
			d1=Array.concat(d1, d0[last]); 
			Array.getStatistics(d1, min, max, mean, std);
			d2=Array.concat(d2, mean);
			return d2;
			exit;
		}
	}
}

// Print to Text Window
function printToText(name, a) {
	title1 = "Text Window";
	title2 = "["+title1+"]";
	f = title2;
	run("Text Window...", "name="+title2+" width=72 height=4 menu");
	print(f, "\\Update:"); // clears the window
	print(f, name);
	n=a.length;
	for (i=0; i<n; i++) {
		if (i==n-1) {
			print(f, d2s(a[i],2)+".");
			exit;
		}
		print(f, d2s(a[i],2)+", ");
	}
}

// This is just like Array.sort(), but it sorts the array by descending values rather than ascending.
function sortDescending(array1) {
	array2=newArray();
	array3=newArray();
	for (i=0;i<array1.length;i++) {
		negValue=-1*array1[i];
		array2=Array.concat(array2, negValue);
		array2=Array.sort(array2);
	}
	for (i=0;i<array2.length;i++) {
		posValue=-1*array2[i];
		array3=Array.concat(array3, posValue);
	}
	return array3;
}