/* 
 *  This script provides an instantaneous conversion from reciprocal space to real  
 *  space for selected area diffraction (SAD) pattern measurements. 
 *  
 *  It assumes that your diffraction pattern was collected using Gatan's 
 *  Digital Micrograph software, and that your image is properly calibrated in 
 *  reciprocal space, i.e. scale bar units display as 1/nm in DM. 
 *  
 *  It also assumes that you have used imageJ's circle tool to measure the spot/ring 
 *  patterns concentric to the (000) direct beam. From the area measurement, the radius
 *  (G) is found. From G = 1/d in reciprocal space, the d-spacing is calculated for  
 *  each measurement made.
 *  
 *  Written by: Mark Koten, Ph.D. (2/2/2018)
*/

// General procedure:
	setMeasurements();
	calcD();
	updateResultsTable();

// This ensures that Area will be set the next time, if it wasn't already...
function setMeasurements() {
	run("Set Measurements...", "area centroid redirect=None decimal=3");
}

// This converts the Area measurement to G (1/nm) and then d (A).
function calcD() {
	G = newArray();
	d = newArray();
	for (row=0; row<nResults; row++) {
		a=getResult("Area",row);
		g=sqrt(a/3.141593);
		D=10/g;
		d=Array.concat(d, D);
		G=Array.concat(G, g);
		setResult("G (1/nm)", row, g);
		setResult("d (A)", row, D);
	}
//	printToText("d (A) = ", d);  
}

// Just renames the updateResults command.
function updateResultsTable() {
	updateResults();
}

// Provides an additional list for user to copy and paste.
function list(name, a) {
    print(name); 
    Array.print(a);
}

// Print to Text Window
function printToText(name, a) {
	title1 = "Text Window";
	title2 = "["+title1+"]";
	f = title2;
	run("Text Window...", "name="+title2+" width=72 height=4 menu");
	print(f, "\\Update:"); // clears the window
	print(f, name);
	n=a.length;
	for (i=0; i<n; i++) {
		if (i==n-1) {
			print(f, d2s(a[i],2)+".");
			exit;
		}
		print(f, d2s(a[i],2)+", ");
	}
}