// Action Bar description file :Kalensbar
run("Action Bar","/plugins/ActionBar/_Kalensbar.txt");
exit();
<startupAction>
run(" Kalensbar");
</startupAction>

<sticky>
<line>
<button>
label=Close this bar
icon=noicon
arg=<close>
</line>

<line>
<button>
	label=Prev Object
	icon=noicon
	arg=<macro>
	
	if ( ojSelectedObject()!=0 && ojImageLink()!=0 ){
	
	ojnum=ojSelectedObject();
		//Real OJnum
		currentImage=ojImageLink();
		ojnum=ojnum-ojFirstObject(currentImage)+1;
		
		if (ojnum!=1){
			ojnum=ojnum-1;
		}
		goToOjnumAll(ojnum);
		
	}
</macro>
</line>



<line>
<button>
	label= Next Obj
	icon=noicon
	arg=<macro>
	if (ojSelectedObject()!=0 && ojImageLink()!=0){
	
	
	currentImage=ojImageLink();
	ojnum=ojSelectedObject();
	
	
		if (ojnum==ojNObjects()){
			ojnum=ojFirstObject(currentImage);
		}else if (currentImage<ojNImages()){
			if (ojnum+1==ojFirstObject(currentImage+1)) {
				ojnum=ojFirstObject(currentImage);
			} 	
		} 
		
		
		ojnum=ojnum-ojFirstObject(currentImage)+1;
		//This addition actually increments the location. The prev line just makes the numbers come out right. 
		ojnum=ojnum+1;
		goToOjnumAll(ojnum);
	}


</macro>

</line>

<line>
<button>
	label= Prev Image
	icon=noicon
	arg=<macro>
	if (ojImageLink()!=0){
	
	
	n=ojImageLink();
    getLocationAndSize(x, y, width, height);

		if (n>1){
			n=n-1;
		}else{
			n=ojNImages();
		}	
		
		while (ojGetImageValue(n, "ID")==0){
			
			if (n>1){
				n=n-1;
			}else{
				n=ojNImages();
			}	
		}

		ojShowImage(n);
		setLocation(x, y);


}

</macro>

</line>


<line>
<button>
	label= Next image
	icon=noicon
	arg=<macro>
	
if (ojImageLink()!=0){
	n=ojImageLink();
    getLocationAndSize(x, y, width, height);

		if (n<ojNImages()){
			n=n+1;
		}else{
			n=1;
		}	
		
		while (ojGetImageValue(n, "ID")==0){
			if (n<ojNImages()){
				n=n+1;
			}else{
				n=1;
			}	
		}

		ojShowImage(n);
		setLocation(x, y);
}
</macro>
</line>


//imageJ array is zero ordered FYI
<line>
<button>
	label= Ch1
	icon=noicon
	arg=<macro>	
	Stack.getActiveChannels(activeChan);	
	activateChan=toString(activeChan,0);

	if (substring(activeChan,0,1)=="1"){
	   temp="0"+substring(activeChan,1);
     	   Stack.setActiveChannels(temp);
	} else {
	   temp="1"+substring(activeChan,1);
	   Stack.setActiveChannels(temp);	
	}	
</macro>
</line>

<line>
<button>
	label= Ch2
	icon=noicon
	arg=<macro>	
	Stack.getActiveChannels(activeChan);
	if (substring(activeChan,1,2)=="1"){
     	   Stack.setActiveChannels(substring(activeChan,0,1)+"0"+substring(activeChan,2));
	} else {
  	   Stack.setActiveChannels(substring(activeChan,0,1)+"1"+substring(activeChan,2));
	}	
</macro>
</line>

<line>
<button>
	label= Ch3
	icon=noicon
	arg=<macro>	
	Stack.getActiveChannels(activeChan);
	if (substring(activeChan,2,3)=="1"){
     	   Stack.setActiveChannels(substring(activeChan,0,2)+"0"+substring(activeChan,3));
	} else {
	   Stack.setActiveChannels(substring(activeChan,0,2)+"1"+substring(activeChan,3));	
	}	
</macro>
</line>
<line>

<button>

	label= Add Note
	icon=noicon
	arg=<macro>
if (ojSelectedObject()!=0){	
	ojnum=ojSelectedObject();
	row=ojIndexToRow(ojnum);
	orig=ojResultString("Notes",row);
	width=512; height=512;
	ojNumOnImage=ojnum-ojFirstObject(ojOwnerIndex(ojnum))+1;
	
	Dialog.create("Notes on Marker Number: "+ojNumOnImage);
	if (orig == "") {
		Dialog.addString("Notes on Marker Number: "+ojNumOnImage, "Write Your Note",75);
	} else  {
		Dialog.addString("Notes on Marker Number: "+ojNumOnImage, orig,75);
	}
	  Dialog.show();
  	value = Dialog.getString();
	ojSetResult("Notes",row, value);
	
}
</macro>
</line>

<line>

<button>

	label= Toggle Bookmark / Unsure
	icon=noicon
	arg=<macro>	
if (ojSelectedObject()!=0){
	
	n=ojSelectedObject();
	row=ojIndexToRow(n);
	ojNumOnImage=n-ojFirstObject(ojOwnerIndex(n))+1;
	
	booktest=ojResult("Bookmarked", row);
	if (booktest==1){
		ojSetResult("Bookmarked", row, 0);
		showMessage("Removed Bookmark for Marker Number: "+ ojNumOnImage);
	} else {
		ojSetResult("Bookmarked", row, 1);
		showMessage("Added Bookmark for Marker Number: "+ojNumOnImage);
	}
}
</macro>
</line>
















<line>
<button>

	label=Toggle Pan
	icon=noicon
	arg=<macro>	
	ojSetTool("hand");
</macro>
</line>

<line>
<button>
	label=Apply Zoom
	icon=noicon
	arg=<macro>	
if (ojSelectedObject()!=0 && ojImageLink()!=0){
		currentimage=ojImageLink();
		ojnum=ojSelectedObject();
		if (ojnum>=ojFirstObject(currentimage) && ojnum<=ojLastObject(currentimage)){
			ojnum=ojnum-ojFirstObject(currentimage)+1;
			
		}else{
			ojnum=1;
		}
		goToOjnumAll(ojnum);
}
</macro>
</line>

<line>
<button>
	label=Save Project
	icon=noicon
	arg=<macro>	
		ojSaveProject();
		showMessage("Project Saved");
		
</macro>
</line>






</sticky>


<codeLibrary>



function ojQualifyApply(rowArray,flag){	
			for (i=0; i<lengthOf(rowArray); i++){
				if(rowArray[i]>0){
					ojQualify(rowArray[i], flag);
				}
			}
		}



function goToOjnumAll(ojnum){

        currentimage=ojImageLink();
		firstoncurrentimage=ojFirstObject(currentimage);
		zoom=getZoom();
		
		totalimages=ojNImages();
		for (n=1; n<=totalimages; n=n+1){
			if(n != currentimage){
				if(ojGetImageValue(n, "ID")!=0){
					ojShowImage(n);
					firstonimage=ojFirstObject(n);
					ojToShow=ojnum+firstonimage-1;
					
					if (ojToShow<=ojLastObject(n)) {
						ojShowObject(ojToShow);
						yoj=ojYPos(1);
						xoj=ojXPos(1);
						ojZoom(zoom,xoj,yoj);
					}
				}
			
			}
		// To return the view to the start
		}
			
		ojShowImage(currentimage);
		ojShowObject(ojnum+firstoncurrentimage-1);
		yoj=ojYPos(1);
		xoj=ojXPos(1);
		ojZoom(zoom,xoj,yoj);
			
}

</codeLibrary>