// Jan Wisniewski, EIB/NCI/NIH, Bethesda, MD

//segments nuclei and measures intensity of the target, corrected for the cytoplasm
//data for individual nuclei are stored in a custom table
//segmentation map, combined into motage with color channels and composite allows confirmation of segmentation process

print("Cell Segmentation Macro\nJan Wisniewski, Experimental Immunology Branch\nNational Cancer Institute, NIH, Bethesda, Maryland");
getDateAndTime(year, month, dayOfWeek, dayOfMonth, hour, minute, second, msec);
print("");
print("run: ", month, "/", dayOfMonth, "/", year, "   at ", hour, ":", minute);
print("");

//  specify folders
res=getDirectory("Choose a Results Directory")
myDir1 = res+"temp1"+File.separator;
File.makeDirectory(myDir1);
myDir2 = res+"temp2"+File.separator;
File.makeDirectory(myDir2);
myDir3 = res+"temp3"+File.separator;
File.makeDirectory(myDir3);
myDir4 = res+"temp4"+File.separator;
File.makeDirectory(myDir4);
myDir5 = res+"temp5"+File.separator;
File.makeDirectory(myDir5);
input=getDirectory("Select a Source Directory");
NAMES=getFileList(input); 

run("Brightness/Contrast...");

//set measured parameters
run("Set Measurements...", "area mean min bounding integrated median display redirect=None decimal=2");

//create custom table
title1 = "Analysis Table"; 
title2 = "["+title1+"]"; 
f=title2; 
run("New... ", "name="+title2+" type=Table"); 
print(f,"\\Headings:Image\tTarget\tID\tBackground(ADUs)\tArea(pixels)\tArea(um2)\tIntensity(ADUs)\tADUs/um2)"); 


//channel setup
open();
ttl=File.nameWithoutExtension;
getDimensions(width, height, channels, slices, frames);
rename("x");
run("Split Channels");
run("Tile");
selectWindow("C1-x");
run("Enhance Contrast", "saturated=0.35");
selectWindow("C2-x");
run("Enhance Contrast", "saturated=0.35");
Dialog.create("Channel selection");
items=newArray("C1-x", "C2-x");
itemz=newArray("Grays", "Blue", "Cyan", "Green", "Yellow" ,"Red", "Magenta");
Dialog.addRadioButtonGroup("Select channel to create mask:", items, 1, 2, "C1-x");
Dialog.addString("Name the mask:", " ");
Dialog.addChoice("Display it in:", itemz, "Red");
Dialog.addMessage("     *     *     *     *     *     *     *     *     *     *");
Dialog.addRadioButtonGroup("Select channel to measure:", items, 1, 2, "C2-x");
Dialog.addString("Name the measured structure:", " ");
Dialog.addChoice("Display it in:", itemz, "Green");
Dialog.show();
MCh=Dialog.getRadioButton();
MNm=Dialog.getString();
MCo=Dialog.getChoice();
OCh=Dialog.getRadioButton();
ONm=Dialog.getString();
OCo=Dialog.getChoice();
print("setup image:", ttl);
print(MNm, MCh, MCo);
print(ONm, OCh, OCo);
close("C1-x");
close("C2-x");

//proces images
for (i=0; i<NAMES.length; i++) {
open(input+NAMES[i]);
ttx=File.nameWithoutExtension;
getPixelSize(unit, pixelWidth, pixelHeight);
pxum2=1/(pixelWidth*pixelHeight);
print("pixel size=",pixelWidth, "x", pixelHeight, unit, "   ", pxum2, "pixels/um2");
rename("x");
run("Split Channels");
selectWindow(MCh);
run(MCo);
run("Enhance Contrast", "saturated=0.35");
	run("Duplicate...", "title=MRGB");
	run("RGB Color");
	saveAs("Tif", myDir5+MNm);
	close();
selectWindow(MCh);
run("Median...", "radius=2");
	run("Threshold...");
	waitForUser("Adjust Threshold - Use Only Slider! - Prior to Clicking OK");
	run("Convert to Mask");
	run("Fill Holes");
	run("Options...", "iterations=8 count=3 pad do=Open");
	run("Watershed");
	setTool("freehand");
splitNuclei=getBoolean("Did any nuclei got split?");
	if(splitNuclei==1) {waitForUser("Select Area Inside Nucleus Around Incorrect Split Line\nHold Shift for multiple selections\nThen Click OK");
		run("Add...", "value=255");
		run("Select None");}
	artNuclei=getBoolean("Do You Need to Exclude Other Artifacts or Edge Objects?");
	if(artNuclei==1) {
		waitForUser("Select Artifacts to Remove, Then Click OK");
		run("Clear");
		run("Invert");
		run("Select None"); }
run("Invert");
saveAs("Tif", myDir1+ttl+"_mask.tif");
rename("mask");
selectWindow(OCh);
run(OCo);
run("Enhance Contrast", "saturated=0.35");
	run("Duplicate...", "title=ORGB");
	run("RGB Color");
	saveAs("Tif", myDir5+ONm);
	close();
selectWindow(OCh);
setTool("freehand");
waitForUser("Select representative background area: e.g. cytoplasm for nucleus\nAdjust contrast, if needed!");
run("Measure");
bckg=getResult("Mean");
run("Select None");
run("Subtract...", "value=bckg");

selectWindow("Analysis Table");
print(f,ttx+"\t"+ONm+"\t"+" "+"\t"+bckg+"\t"+" "+"\t"+" "+"\t"+" "+"\t"+" ");

selectWindow("mask");
sel=getBoolean("How many objects would you like to analyze?", "All", "Selected only");
if(sel==1) {run("Find Maxima...", "prominence=100 exclude output=List");
			selectWindow("Results");
			Table.sort("X");
			rs=Table.size();
			Table.rename("X_Y_list");	
roiManager("Show All with labels");
	for (q = 0; q < rs; q++) {m=q+1001;
			selectWindow("X_Y_list");
			xxt=Table.get("X", q);
			yyt=Table.get("Y", q);
			selectWindow("mask");
			run("Duplicate...", " ");
			rename("s");
			setTool("wand");
			doWand(xxt, yyt);
			run("Clear Outside");
				roiManager("Add");
				run("Select None");
				run("Invert");
				run("Flatten");
				saveAs("Tif", myDir2+ttx+"_selected_"+m);
				close();
				selectWindow("s");
				run("32-bit");
				run("Divide...", "value=255");
				imageCalculator("Multiply create", "C2-x","s");
				run("Restore Selection");
				run("To Bounding Box");
				run("Crop");
				saveAs("Tif", myDir3+ttx+"_area_"+m);
				close();
				selectWindow("s");
				run("Enhance Contrast", "saturated=0.35");
				run("Restore Selection");
				run("To Bounding Box");
				run("Crop");
				saveAs("Tif", myDir4+ttx+"_mask_"+m);
				close();	}
				close("X_Y_list");	}
else {Dialog.create("  ");
Dialog.addNumber("How many regions would you like to analyze?", 1);
Dialog.show();
obj=Dialog.getNumber();
setTool("wand");
roiManager("Show All with labels");
for (j = 0; j < obj; j++) {k=j+1001;
				selectWindow("mask");
				run("Duplicate...", " ");
				rename("s");
				waitForUser("Select the first region, followed by the next one, etc.");
				run("Clear Outside");
				roiManager("Add");
				run("Select None");
				run("Invert");
				run("Flatten");
				saveAs("Tif", myDir2+ttx+"_selected_"+k);
				close();
				selectWindow("s");
				run("32-bit");
				run("Divide...", "value=255");
				imageCalculator("Multiply create", "C2-x","s");
				run("Restore Selection");
				run("To Bounding Box");
				run("Crop");
				saveAs("Tif", myDir3+ttx+"_area_"+k);
				close();
				selectWindow("s");
				run("Enhance Contrast", "saturated=0.35");
				run("Restore Selection");
				run("To Bounding Box");
				run("Crop");
				saveAs("Tif", myDir4+ttx+"_mask_"+k);
				close();	}	}
				close("mask");
				close(OCh);
				roiManager("Delete");
//myDir2=getDirectory("Choose a Directory");				
tn2=getFileList(myDir2);
for (h = 0; h < tn2.length; h++) {open(myDir2+tn2[h]);	}
run("Images to Stack", "name=Stack title=[] use");
run("Z Project...", "projection=[Min Intensity]");
run("Invert");
close("Stack");							
open(myDir1+ttl+"_mask.tif");
rename("all");
//run("Invert");				
imageCalculator("Average create", "MIN_Stack","all");
//saveAs("Tif", res+ttx+"_selection");
saveAs("Tif", myDir5+"selected");
close();
close("all");
close("MIN_Stack");
//myDir2=getDirectory("Choose a Directory");				
tn2=getFileList(myDir2);
for (h = 0; h < tn2.length; h++) 
ok=File.delete(myDir2+tn2[h]);
//myDir1=getDirectory("Choose a Directory");				
tn1=getFileList(myDir1);
for (g = 0; g < tn1.length; g++) 
ok=File.delete(myDir1+tn1[g]);

		setBatchMode(true);

tn3=getFileList(myDir3);
tn4=getFileList(myDir4);
for (q = 0; q < tn4.length; q++) {Numb=q+1;
			open(myDir4+tn4[q]);
			run("Measure");
			selectWindow("Results");
			areapx=getResult("RawIntDen");
			areaum2=areapx/pxum2;
			close();
			open(myDir3+tn3[q]);
			run("Measure");
			selectWindow("Results");
			oint=getResult("RawIntDen");
			ointum2=oint/areaum2;
			close();
			close("Results");

			selectWindow("Analysis Table");
			wait(500);
			print(f," "+"\t"+MNm+"\t"+Numb+"\t"+" "+"\t"+areapx+"\t"+areaum2+"\t"+oint+"\t"+ointum2);	}
			
for (q = 0; q < tn4.length; q++) 
ok=File.delete(myDir4+tn4[q]);
for (e = 0; e < tn3.length; e++) 
ok=File.delete(myDir3+tn3[e]);

		setBatchMode(false);

open(myDir5+ONm+".tif");
rename(ONm);
open(myDir5+MNm+".tif");
rename(MNm);
imageCalculator("Add create", ONm, MNm);
rename(ttx);
open(myDir5+"selected.tif");
rename("selected");
run("Images to Stack", "name=Stack title=[] use");
run("Make Montage...", "columns=2 rows=2 scale=0.5 border=4 font=40 label");
run("Scale Bar...", "width=50 height=4 font=25 color=White background=None location=[Lower Right] bold overlay");
run("Flatten");
saveAs("Tif", res+ttx+"_montage");
close();
close("Montage");
close("Stack");

tn5=getFileList(myDir5);
for (r = 0; r < tn5.length; r++)
ok=File.delete(myDir5+tn5[r]);	}

close("B&C");
close("Threshold");
close("ROI Manager");

selectWindow("Analysis Table");
saveAs("Text", res+"Analysis_Results.csv");
close("Analysis Table");
close("Results");
selectWindow("Log");
saveAs("Text", res+"Log");
close("Log");

ok = File.delete(myDir1);
ok = File.delete(myDir2);
ok = File.delete(myDir3);
ok = File.delete(myDir4);
ok = File.delete(myDir5);