var sampleMin = newArray();
var sampleMax = newArray();
var sampleMean= newArray();
var sampleStdDev = newArray();
var samples = newArray();

macro "Roughness approximater" {

/*
 * Roughness approximater
 * 
 * Macro to determine the 'roughness' of a surface in a binary AmiraMesh file
 * Assumptions:	
 * 		Object oriented laterally i.e. slices look through the xy plane / along the z axis	
 * 		Z = 0 is the bottom, Z = max is the top
 * 		the surface is defined as the FIRST edge encountered relative to the base of the object
 * Macro fails for complicated structures, or objects that deviate significantly from a predominantly 
 * smooth surface relative to the base
 * 
 * Measurements are all in pixels
*/

print("\\Clear");
IJ.log("Starting analysis");
IJ.log("*****************");
dir = getDirectory("Choose Source Directory ");
dir1 = getDirectory("Save location for results");
  extension = ".am";

  setBatchMode(true);
  n = 0;
  processFolder(dir);

Sample_Name = samples;
Min = sampleMin;
Max = sampleMax;
Mean = sampleMean;
StdDev = sampleStdDev;


Array.show("Summary", Sample_Name, Min, Max, Mean, StdDev);
summaryName = replace(dir, ":", "-");
summaryName = replace(summaryName, " ", "_");
saveAs("Results", dir1+"Summary Results for "+summaryName+".txt");

  function processFolder(dir) {
     list = getFileList(dir);
     for (i=0; i<list.length; i++) {
          if (endsWith(list[i], "/"))
              processFolder(dir+list[i]);
          else if (endsWith(list[i], extension))
             processImage(dir, list[i]);
      }
  }


  function processImage(dir, name) {
  	samples = Array.concat(samples, name);
  	
		run("Amira...", "amirafile=["+dir+name+"]"); 

getVoxelSize(Vwidth, Vheight, Vdepth, unit);
startTime = getTime();
name = substring(name, 0, indexOf(name, ".am"));

run("Set Scale...", "distance=0 known=0 pixel=1 unit=pixel");		// Avoid any scaling issues
run("Reslice [/]...", "output=1 start=Bottom avoid");				// Reorient object
setThreshold(1, 255);												// Assuming binary already
setOption("BlackBackground", true);
run("Convert to Mask", "method=Default background=Dark black");
run("Find Edges", "stack");											// Find interfaces
run("Skeletonize", "stack");										// Reduce to single line
getDimensions(width,height,channels,Tslices,frames);

EdgeArray = newArray(width);
EdgeArrayMin = newArray(Tslices);
EdgeArrayMax = newArray(Tslices);
EdgeArrayMean = newArray(Tslices);
EdgeArrayStdDev = newArray(Tslices);

for (z=1; z<Tslices; z++){
	temp = round(z*100/Tslices);
	tempDisp =(temp-temp%5); 
		showStatus("Processing dataset: "+name+" ----- "+tempDisp+"% Complete");
														// Update status bar - helpful to check for stalling
setSlice(z);
for (x=0; x<width; x++){
	Edge = 0;
	y = 0;
	while(Edge ==0 && y<height){
			if(getPixel(x,y) == 255){
EdgeArray[x]=y;
 Edge=1;
}
		y++;
		};
		
	};
	

Array.getStatistics(EdgeArray, min, max, mean, stdDev);
EdgeArrayMin[z] = min;
EdgeArrayMax[z] = max;
EdgeArrayMean[z] = mean;
EdgeArrayStdDev[z] = stdDev;
Array.fill(EdgeArray, 0);
};
endTime = getTime();
totalTime = (endTime - startTime)/1000;

// Write out to Log for confirmation
print("Summary report for "+name);
print("Runtime (s): "+totalTime);
print("----------------------------------");
print(" Min Max Mean StdDev");
Array.getStatistics(EdgeArrayMin, Zmin, Zmax, Zmean, ZstdDev);
print("Min: "+Zmin+" "+Zmax+" "+Zmean+" "+ZstdDev);
sampleMin = Array.concat(sampleMin, Zmean);
Array.getStatistics(EdgeArrayMax, Zmin, Zmax, Zmean, ZstdDev);
print("Max: "+Zmin+" "+Zmax+" "+Zmean+" "+ZstdDev);
sampleMax = Array.concat(sampleMax, Zmean);
Array.getStatistics(EdgeArrayMean, Zmin, Zmax, Zmean, ZstdDev);
print("Mean: "+Zmin+" "+Zmax+" "+Zmean+" "+ZstdDev);
sampleMean = Array.concat(sampleMean, Zmean);
Array.getStatistics(EdgeArrayStdDev, Zmin, Zmax, Zmean, ZstdDev);
print("StdDev: "+Zmin+" "+Zmax+" "+Zmean+" "+ZstdDev);
print("----------------------------------");

sampleStdDev = Array.concat(sampleStdDev, Zmean);
Minimum = EdgeArrayMin;
Maximum = EdgeArrayMax;
Mean = EdgeArrayMean;
StdDev = EdgeArrayStdDev;


// Write to Results & save
Array.show("Results (row numbers)", Minimum, Maximum, Mean,StdDev);
saveAs("Results", dir1+"Full Results for "+name+".csv");
run("Summarize");
IJ.deleteRows(0, Tslices-1);
saveAs("Results", dir1+"Summary Results for "+name+".csv");
run("Close", "Results");
}

}