// DM4 Conversion script
// Based on recursiveTiffConvert.txt, Written by Curtis Rueden Last updated on 2011 Feb 22
// Developed further by M Foley, ACMM, USYD, 2016
// v1.6-1018

// Recursively converts files to TIFF using Bio-Formats.

//   - Save as OME-TIFF using Bio-Formats Exporter, to preserve metadata
//   - Run garbage collection after each exported file
//   - Also enhances contrast (stretching) and running Gaussian filter to clear up noise

ext = "DM4"; // this variable controls the extension of source files

requires("1.39u");
inDir = getDirectory("Choose Directory Containing " + ext + " Files ");
outDir = getDirectory("Choose Directory for TIFF Output ");
setBatchMode(true);
processFiles(inDir, outDir, "");
print("-- Done --");

function processFiles(inBase, outBase, sub) {
  flattenFolders = true; // this flag controls output directory structure
  print("-- Processing folder: " + sub + " --");
  list = getFileList(inBase + sub);
  if (!flattenFolders) File.makeDirectory(outBase + sub);
  for (i=0; i<list.length; i++) {
    path = sub + list[i];
    upath = toUpperCase(path);
    if (endsWith(path, "/")) {
      // recurse into subdirectories
      processFiles(inBase, outBase, path);
    }
    else if (endsWith(upath, "." + ext)) {
      print("-- Processing file: " + path + " -- File: "+i+1+" of " + list.length);
      run("Bio-Formats Importer", "open='" + inBase + path + "' color_mode=Default view=[Standard ImageJ] stack_order=Default use_virtual_stack");
      run("Enhance Contrast...", "saturated=0.4 normalize");
      run("Gaussian Blur...", "sigma=3");
outFile = outBase + path + ".tif";
      if (flattenFolders) outFile = replace(outFile, "/", "_");
      run("Bio-Formats Exporter", "save=[" + outFile + "] compression=Uncompressed");
      close();
      run("Collect Garbage");
    }
  }
}