// Action Bar description file :oli_action_bar
run("Action Bar","/plugins/ActionBar/LISH_Shortcuts.ijm");
exit;

<text>Common Tools
<line>
<button>
label=Duplicate
icon=noicon
arg=<macro>
run("Duplicate...");
</macro>
<button>
label=Rescale
icon=noicon
arg=<macro>
run("Scale...");
</macro>
</line>
<line>
<button>
label=Set Voxel Size
icon=noicon
arg=<macro>
run("Properties...");
</macro>
<button>
label=Set Scalebar
icon=noicon
arg=<macro>
run("Scale Bar...");
</macro>
</line>

<line>
<button>
label=Show LUT
icon=noicon
arg=<macro>
setBatchMode(true);
name = getTitle();
getLut(reds, greens, blues);
getMinAndMax(min, max);
bd = bitDepth();

newImage("LUT for"+name, bd+"-bit ramp", 256, 45, 1);
makeRectangle(0,25,256,25);
run("Clear", "slice");
run("Select None");
setLut(reds, greens, blues);
setColor(255, 255, 255);
w = getStringWidth(max);
Overlay.drawString(""+min, 2, 42, 0.0);
Overlay.drawString(""+max, 254-w, 42, 0.0);
Overlay.show();
run("Flatten");
//setMinAndMax(min,max);
setBatchMode(false);
</macro>
<button>
label=Z Project...
icon=noicon
arg=<macro>
run("Z Project...");
</macro>
</line>
<line>
<button>
label=Reorder Hyperstack
icon=noicon
arg=<macro>
run("Re-order Hyperstack ...");
</macro>
<button>
label=Color Coded Projection
icon=noicon
arg=<macro>
run("Temporal-Color Code");
</macro>
</line>
<line>
<button>
label=Series Labeler
icon=noicon
arg=<macro>
run("Label...");
</macro>
<button>
label=Close Others
icon=noicon
arg=<macro>
close("\\Others");
</macro>
</line>
<text> File Export
<line>
<button>
label=Export Luxendo Files
icon=noicon
arg=<macro>

dir = getDirectory("Where are the HDF5 files?");
saveDir =  getDirectory("Save Directory");
setBatchMode(true);
saveFiles(dir, saveDir);
setBatchMode(false);
showMessage("Finished");

function saveFiles(dir, saveDir) {
	files = getFileList(dir);
	for(i=0; i<files.length;i++) {
		if(endsWith(files[i],"/")) {
			saveFiles(dir+files[i], saveDir);
		}
		if(endsWith(files[i],".h5")) {
			print("Opening "+files[i]);

			folderName = substring(dir, lastIndexOf(dir,"\\")+1,lengthOf(dir)-1);
			
			timepoint = substring(files[i], 9, lengthOf(files[i])-3);
			view = parseInt(substring(folderName,indexOf(folderName,"_")+1,indexOf(folderName,"_")+2));
			channel = substring(folderName,lastIndexOf(folderName, "_")+1,lengthOf(folderName));
			if (matches(files[i], ".*Right.*")) {
				camera = 1;
			} else {
				camera = 0;
			}

			finalName = "Luxendo_A"+(2*view+camera)+"_C"+channel+"_T"+timepoint+".tif";
			saveAt = saveDir;

			if(!File.exists(saveAt+finalName)) {
			
				run("Scriptable load HDF5...", "load="+dir+files[i]+" datasetnames=Data nframes=1 nchannels=1");
				if (matches(files[i], ".*Right.*")) {
					print("Mirroring "+files[i]);
					run("TransformJ Mirror", "x-mirror");
				}
			
			
			
				print("Saving tiff", finalName);
				
				saveAs("Tiff", saveAt+finalName);
				run("Close All");
			}
		}
	}
}
</macro>
</line>
<line>
<button>
label=Rename Lattice Files
icon=noicon
arg=<macro>

dir = getDirectory("Where are the Lattice Files?");

run("Clear Results");
setBatchMode(true);
renameFiles(dir);
setBatchMode(false);
saveAs("results", dir+"Resaves-timestamps.csv");
showMessage("Lattice File Renaming Done. \nTimestamps resaved as text.");
function renameFiles(dir) {
	
	files = getFileList(dir);
	for(i=0; i<files.length;i++) {
		if(endsWith(files[i],"/")) {
			//renameFiles(dir+files[i]);
		}
		if(endsWith(files[i],".tif")) {
			print("Renaming "+files[i]);
			filename   = substring(files[i],0,indexOf(files[i], "nm_")+2);
			timestamps = substring(files[i],indexOf(files[i], "nm_")+3,lengthOf(files[i])-4);
			
			t1 = substring(timestamps, 0,indexOf(timestamps,"_")-4);
			t2 = substring(timestamps,indexOf(timestamps,"_")+1, lengthOf(timestamps)-7);
			k = nResults;
			print(filename, t1,t2);

			success = File.rename(dir+files[i], dir+filename+".tif");
			setResult("Label", k, filename);
			setResult("Delta T [ms]", k, parseInt(t1));
			setResult("Abs T [ms]", k, parseInt(t2));
			setResult("Rename Success", k, success);
			updateResults();
			}
		}
}
</macro>
</line>