function CIJA(input, output, filename,scale) //converts image to 8 bit, sets the image scale based on the magnification specified by user, 
									  //auto thresholds, inverts image, and analyzes particles. All calculations are based on IEST-STD-CC1246E

	{
		open(input + filename);
		run("8-bit");
		sensor_x=23500*scale; //uses the known sensor size of the camera to calculate the image size with the magnification used.
		sensor_y=15600*scale;
		total_area = sensor_x*sensor_y;
		run("adaptiveThr ", "using=Mean");
		run("Invert");
		run("Analyze Particles...", "clear");
		count = nResults(); //num particles is num of results
		resultsArray=newArray();
		for(i=0;i<count;i++) //for each particle retrieves the results from Analyze Particles function and adds it to the results array
			{
				resultsArray=Array.concat(resultsArray,getResult("Area",i));
				covered = covered + getResult("Area",i); //area covered is sum of area of each particle
			}
		Array.getStatistics(resultsArray,min,max,mean,stdDev);
		avg = mean;
		PAC = 10*(covered/total_area); //Percent area coverage is total area covered/total image area
		covered = covered*0.1; //adjusts area covered to fit units
		clean = pow(10,(sqrt(((7.244+(0.43429*log(PAC)))/0.926)))); //calculates cleanliness level
		result = newArray(total_area,count,avg,covered,PAC,clean); //adds all the data to an arrray and returns it
		return result;
	}

macro "CIJA Action Tool - C059T3e16C"	
	{
	run("8-bit");
	run("adaptiveThr "); //runs thresholder for the first image so user can adjust the threshold
	input = getInfo("image.directory"); //gets image location
	name = getInfo("image.filename"); //gets image filename
	setBatchMode(true);
	list = getFileList(input);
	total_area= newArray(list.length);
	count= newArray(list.length);
	avg= newArray(list.length);
	area_covered= newArray(list.length);
	PAC= newArray(list.length);
	clean = newArray(list.length);
	mag = newArray(list.length);
    Dialog.create("CIJA"); //creates a window for user to enter magnification levels for each image and specify where to output data
	Dialog.addMessage("Please fill out the fields below");
	Dialog.addString("Enter output location (Ex. C:/Users/jjlydon/Desktop/)","");
	Dialog.addMessage("(Cannot be the same as image location)");
	Dialog.addNumber("Enter magnification used for "+name,1);
	Dialog.addCheckbox("Process all images in current folder",false);
	Dialog.show();
	output = Dialog.getString();
	mag[0] = Dialog.getNumber();
	all = Dialog.getCheckbox();
	if(all==true)
		{
			Dialog.create("Magnification");
			Dialog.addMessage("Enter magnification used for each image");
			
			for(i=1;i<list.length;i++)
				{
					Dialog.addNumber(list[i],0);
				}
			Dialog.show();
			for(i=1;i<list.length;i++)
				{
					mag[i] = Dialog.getNumber();
				}
		}
	
	for(i=0;i<list.length;i++)
		{
		result = CIJA(input, output, list[i],mag[i]); //runs CIJA function and puts output data into arrays for each parameter
		total_area[i] = result[0];
		count[i] = result[1];
		avg[i] = result[2];
		area_covered[i] = result[3];
		PAC[i] = result[4];
		clean[i] = result[5];
		if(all==false) //only processes first image if chosen
			{
				i=list.length;
			}
		}	
	setBatchMode(false);
	Table.create("Data"); //prints data in a table
	Table.setColumn("File",list);
	Table.setColumn("Total Area",total_area);
	Table.setColumn("Count",count);
	Table.setColumn("Area Covered",area_covered);
	Table.setColumn("Avg Size",avg);
	Table.setColumn("PAC",PAC);
	Table.setColumn("Cleanliness Level (spheres)",clean);
	Table.update;
	saveAs("Results", output + "Data.csv");
	}