// batchTiffConvert.txt
// Author: Melissa Linkert <melissa at glencoesoftware.com>
// Last updated: 28 March 2011

// Converts all files in a directory to TIFF using the Bio-Formats macro
// extensions.  There will either be one TIFF file per plane or one TIFF file
// per input file, depending upon the value of 'oneFilePerSlice' (see below).

// By default, one TIFF file is created for each plane in each file.

directory = getDirectory("Choose input files");
IJ.log("Input: " + directory);
fileList = getFileList(directory);
IJ.log(fileList.length + " files.");

outputDirectory = getDirectory("Choose output directory");
IJ.log("Output: " + outputDirectory);

run("Bio-Formats Macro Extensions");
setBatchMode(true);

for (i=0; i<fileList.length; i++) {
	file = directory + fileList[i];
	IJ.log("\nProcessing " + file);
	Ext.setId(file);
	Ext.openImagePlus(file);
	Ext.getSizeC(sizeC);
	IJ.log("Number of channels: " + sizeC);
	if(sizeC > 1){
		run("Split Channels");
	}
	subDirs = newArray(sizeC);
	for(c=0;c<sizeC;c++){
		subDirs[c] = outputDirectory + "C_" + (c + 1);
		if(!File.exists(subDirs[c])){
			File.makeDirectory(subDirs[c]);
		}
	}
	titles = getList("image.titles");
	for(j=0; j<titles.length; j++){
		selectWindow(titles[j]);
		index = lastIndexOf(titles[j], ".");
		titles[j] = substring(titles[j], 0, index);
		filename = subDirs[j] + File.separator + titles[j] + "_C" + (j+1) + ".tiff";
		IJ.log("Saving " + filename);
		saveAs("TIFF", filename);
		close();
	}
	Ext.close();
}

IJ.log("\nFinished");
showStatus("Finished.");
setBatchMode(false);

function saveFile(outFile) {
   run("Bio-Formats Exporter", "save=[" + outFile + "] compression=Uncompressed");
}