//This is useful to correct for z- and xy- drift across timepoints.
//Uses TurboRegplugin to align a hyperstack in z and/or in xy.
//The alignment is based on a max projection of the xz reslice for
//the z-alignment, and a regular xy max projection for xy alignment
//Currently only can use one of the channels to align.
//This will not align the slices of a particular individual time point,
//for that use Align Z forEachTimePoint

	turboregstring="TurboReg";
	List.setCommands;
	if(List.get(turboregstring)=="")turboregstring="TurboReg ";
	if(List.get(turboregstring)=="") exit("This macro requires TurboReg");
	stackregstr="StackReg";
	if(List.get(stackregstr)=="")stackregstr="StackReg ";
	if(List.get(stackregstr)=="") exit("This macro requires "+stackregstr);

	title=getTitle();
	IID=getImageID();
	oIID=IID;
	getVoxelSize(px,py,pz,unit);
	getDimensions(w,h,chs,sls,frms);
	substack="1-"+sls;
	bits=bitDepth();
	logarray=false;
	setPasteMode("Copy");
	Zname=title + "-Zalign";

	if(sls==1 || frms==1) exit("Requires hyperstack with multi frames");
	if(bits==24){
		charray=newArray("all","red","green","blue");
	}else{
		charray=newArray(chs);
		for(i=0;i<chs;i++){charray[i]=toString(i+1);}
	}
	ptarray=false;
	srarray=false;
	list=getList("window.titles");
	for(i=0;i<list.length; i++){
		if(list[i]!="B&C" && list[i]!="Log"){
			if(eval("script","WindowManager.getWindow(\""+list[i]+"\").getClass().getName();")=="ij.text.TextWindow"){
				if(eval("script","WindowManager.getWindow(\""+list[i]+"\").getResultsTable()")!=""){
					print("Results Table found: "+list[i]);
					selectWindow(list[i]);
					print(Table.size);
					if(Table.size==(frms-1) && indexOf(Table.headings,"Frame")>-1 && indexOf(Table.headings,"SourceX1")>-1 ){
						print("Results Table found: "+list[i]+" as a StackReg Table");
						ptarray=true;
						srarray=true;
					}
				}
			}
		}
	}
	if(nResults>0 && nResults%frms==0) {ptarray=true;}
	if(!ptarray){
		logstr=split(getInfo("log"),"\n");
		ll=logstr.length;
		st=-1;end=-1;
		for(i=0;i<logstr.length;i++){
			if(startsWith(logstr[i],"Timepoint ")){if(st==-1)st=i; else end=i;}
		}
		if(st!=-1){
			logstr=Array.slice(logstr,st,end+1);
			if(logstr.length==(frms-1)) {logarray=true; ptarray=true;}
		}
	}
	whicharraystr="";
	if(ptarray)whicharraystr="Use locations from ";
	if(srarray)whicharraystr=whicharraystr+"StackReg Table";
	else if(logarray)whicharraystr=whicharraystr+"Log";
	else whicharraystr=whicharraystr+"Results Table";
	xyzchoice=newArray("None","Auto",whicharraystr);

	Dialog.create("Choices");
	Dialog.addMessage("XYZ-adjusting stack: "+title);
	Dialog.addCheckbox("Z-align slices for each frame",false);
	Dialog.addChoice("XY-align frames?", xyzchoice, xyzchoice[1]);
	Dialog.addChoice("Z-align frames?", xyzchoice, xyzchoice[1]);
	Dialog.addMessage("Just for Auto:");
	Dialog.addString("Substack (for xy z-proj):", substack);
	Dialog.addCheckbox("Check changes before accepting?",true);
 	Dialog.addChoice("XY Ch:", charray, "2");
 	Dialog.addChoice(" Z Ch:", charray, "1");
	if(!ptarray){
		Dialog.addMessage("You can also use this macro by first measuring one or\na set of points for each time point, or a previous \nrun with Log data, or a StackReg Table");
	}
	Dialog.show();

	zaligneachfr=Dialog.getCheckbox();
	xymode=Dialog.getChoice();
	zmode=Dialog.getChoice();
	doz=(zmode!=xyzchoice[0]);
	doxy=(xymode!=xyzchoice[0]);
	substack=Dialog.getString();
	autoaccept=!Dialog.getCheckbox();
	xychchoice=Dialog.getChoice();
	zchchoice=Dialog.getChoice();
	
	if(xymode==zmode && xymode==whicharraystr){
		exit("XY and Z can't both use ptarray");
	}

	//chcrgb="";
	//if(chs==1) {chcrgb=chchoice; chchoice="1"; if(chcrgb=="red") rgbc=3; else if(chcrgb=="green") rgbc=5; else if(chcrgb=="blue") rgbc=6;}
	//chchoice=parseInt(chchoice);
	
	if(zaligneachfr){
		//This aligns the slices of each individual time point.
		//This is useful to correct for movement artifact within a timepoint.
		//May be useful to run this first, then Align Hyperstack.
		
		if(isOpen("AJZALIGNTEMP")) exit("Please close AJZALIGNTEMP");
		//if(chs>1) run("Stack to RGB");
		title=getTitle();

		for(i=1;i<=frms;i++){
			selectWindow(title);
			run("Duplicate...", "title="+i+" duplicate frames="+i);
			if(chs>1)Stack.setChannel(xychchoice);
			run(stackregstr, "transformation=Affine");
			if(i!=1) run("Concatenate...", "stack1=1 stack2="+i+" title=AJZALIGNTEMP");
		}
		rename(title+"-slicealign");
		run("Stack to Hyperstack...", "order=xyczt(default) channels="chs" slices="+sls+" frames="+frms);
	}

	startsub=1; endsub=sls;
	if(substack!="") {
		if(indexOf(substack,"-")==-1){
			startsub=round(substack);
			endsub=round(substack);
		} else {
			substa=split(substack,"-");
			startsub=parseInt(substa[0]);
			endsub=parseInt(substa[1]);
		}
		if(startsub>endsub) {tempsub=startsub; startsub=endsub; endsub=tempsub;}
	}
	xyaccepted=true;
	if(doxy){
		if(xymode=="Auto"){
			if(srarray){
				selectWindow("StackReg Results");
				IJ.renameResults("StackReg Results","StackReg Results z");
			}
			selectImage(IID);
			run("Z Project...", "start=startsub stop=endsub projection=[Max Intensity] all");
			Stack.setFrame(1); Stack.setChannel(xychchoice);
			zid=getImageID();
			run(stackregstr,"transformation=Translation show");
			if(!autoaccept){
				waitForUser("Check StackReg");
				xyaccepted=getBoolean("Accept xy-reg changes?");
			}
			selectImage(zid); close();
		}
		if(xyaccepted) run("Image Translator by Pt", "align=[First slice] adjust");
	}

	z=newArray(frms);

	if(!xyaccepted && doz){if(!getBoolean("Run Z-align anyway?"))exit();}
	
	if(doz){
		zaccepted=true;
		if(zmode=="Auto"){
			z[0]=0;
			bh=h*0.15;
			makeRectangle(0, h/2-bh/2, w, bh);
			run("Reslice [/]...", "start=Top");
			rid=getImageID();
			run("Z Project...", "projection=[Max Intensity] all");
			rzid=getImageID();
			selectImage(rid); close();
			selectImage(rzid); Stack.setChannel(zchchoice); Stack.setFrame(1);
			getDimensions(rzw, rzh, rzch, rzsl, rzfrs);
			zfac=rzh/sls;
			run(stackregstr,"transformation=Translation show");
			if(isOpen("Refined Landmarks")){
				//print("[Refined Landmarks]","\\Clear");
				//print("[Refined Landmarks]","\\Close");
			}
			print("[Results]","\\Clear");
			print("[Results]","\\Close");
			selectWindow("StackReg Results");
			info=getInfo("window.contents");
			info=split(info,"\n");
			for(i=1;i<info.length;i++){
				line=split(info[i],"\t");
				fr=parseInt(line[0]);
				z[fr-1]=(parseFloat(line[2])-parseFloat(line[4]))/zfac+z[fr-2];
				print(""+fr+" "+z[fr-1]);
			}
			selectImage(rzid); 
			if(!autoaccept) {
				waitForUser("Check reslices");
				title=getTitle();
				isZadj=call("ajs.tools.AJ_Misc_Plugins.isZAdjusted",title);
				if(isZadj)zaccepted=getBoolean("Accept z-reg changes?");
				else {
					IJ.log("No Z-adjusting necessary");
					zaccepted=false;
				}
		 		
			}
			selectImage(rzid); close();
		}//not ptarray
	
		if(zaccepted){
			run("Image Translator by Pt", "align=[First slice] stackreg");
		} //z accepted
	}//doz
	
	
 //if(doxy && stilldo)
	print("XYZ Registration completed");
	wait(100);
	showProgress(0.5);
	wait(100);
	showProgress(1.0);