//Stack Combiner

macro "Stack Combiner"{

	//saveSettings();

	currtit=getTitle();
	nim=nImages;
	if (nim<2) exit("Not enough images are open");
  	else {
		imagetitles=newArray(nim);
		for (i=1; i<=nim; i++) {
			selectImage(i);
			imagetitles[i-1]=getTitle;
		}
	}
 	Dialog.create("Stack Combiner");
	Dialog.addChoice("Target Stack: ", imagetitles, currtit);
	next=imagetitles[0];
	if(next==currtit) next=imagetitles[1];
	Dialog.addChoice("Source Stack: ", imagetitles, next);
	Dialog.addChoice("Paste Mode: ",newArray("Copy","Max","Transparent-zero"),"Transparent-zero");
	Dialog.addCheckbox("Prioritize first stack?",true);
	Dialog.addCheckbox("Manual offset?",false);
	Dialog.addNumber("x offset:",0);
	Dialog.addNumber("y offset:",0);
	Dialog.show();
	left=Dialog.getChoice();
	right=Dialog.getChoice();
	pmode=Dialog.getChoice();
	pfs=Dialog.getCheckbox();
	manual=Dialog.getCheckbox();
	x=Dialog.getNumber();
	y=Dialog.getNumber();

	comp=false;

	selectWindow(left);
	Stack.getPosition(ch,sl,frm);
	selectWindow(right);
	getDimensions(w,h,chs,sls,frms);
	Stack.setChannel(ch);
	run("Select All");
	run("Copy");
	selectWindow(left);
	run("Duplicate...", "title=temp");
	getDimensions(wt,ht,chst,slst,frmst); if(chst>1) Stack.setChannel(ch);
	if(x!=0)x=wt-x;
	if(y!=0)y=ht-y;

	if(!manual){
		flags=-1;
		leftButton=16;
		centerButton=8;
		setPasteMode("Max");
		snapshot();
		isok=true;
		rtsd=true;
		while(isok){
			while (flags&leftButton!=0) {getCursorLoc(xc, yc, zc, flags); wait(100);
}
			getCursorLoc(x, y, z, flags);
			while (flags&leftButton==0) {
				checkchange=false;
				while (flags&centerButton!=0) {getCursorLoc(xc, yc, zc, flags); wait(100); checkchange=true;}
				if(checkchange)rtsd=!rtsd;
				reset();
				//snapshot();
				getCursorLoc(x, y, z, flags);
				maxxy=maxOf(x,y);
				//if(maxxy==x) makeRectangle(x,0,w,h);
				//else makeRectangle(0,y,w,h);
				if(rtsd) {y-=0.5*h;}
				else {x+=-0.5*w; }
				makeRectangle(x,y,w,h);
				run("Paste");
				wait(100);
			}
			isok=!getBoolean("x:"+x+" y:"+y+" sound ok?");
		}
	}
	close();
	//offset=maxxy;
	//if(maxxy==y) bottom=true;
	//else bottom=false;

	setPasteMode(pmode);

	selectWindow(left);
	getDimensions(widl, heil, chl, slicesl, fr);
	if(chl>1) comp=true;
	Stack.getPosition(channel, sll, frame);
	bits=bitDepth();

	mingo=newArray(chl);
	maxgo=newArray(chl);
	getMinAndMax(mingo[0],maxgo[0]);

	if(comp) {
		colors=newArray(chl);
		for(k=0;k<chl;k++){
			Stack.setChannel(k+1);
			getMinAndMax(mingo[k],maxgo[k]);
			getLut(reds,greens,blues);
			if(reds[1]) colors[k]="Red"; else if(greens[1]) colors[k]="Green"; else colors[k]="Blue";
		}
	}

	selectWindow(right);
	getDimensions(widr, heir, chr, slicesr, fr);
	if(chr!=chl) exit("Must have same number of channels");
	Stack.getPosition(channel, slr, frame);
	if(bits!=bitDepth()) exit("Files have different bit depths, no can do.");

	starter=minOf(slr,sll)-1;
	ender=minOf(slicesl-sll, slicesr-slr);
	begfac=maxOf(slr,sll)-minOf(slr,sll);
	endfac=maxOf(slicesl-(sll+ender),slicesr-(slr+ender));

	newwid=widl; newhei=heil;
	//if(bottom) newhei=offset+heir;
	//else newwid=offset+widr;
	newhei=y+heir; newwid=x+widr;

	bitbit=""+bits+"-bit";
	if(bits==24) bitbit="RGB";
	noslices=starter+ender+1+begfac+endfac;
	setBatchMode(true);
	if(!comp) newImage(left+"-AJCombine", bitbit+" Black", newwid, newhei, noslices);
	else run("Hyperstack...", "title=["+left+"-AJCombine] type="+bitbit+" display=Composite width="+newwid+" height="+newhei+" channels="+chl+" slices="+noslices+" frames=1");
	priority=0;
	if(pfs) priority=1;


	for(i=(0-begfac);i<(noslices-begfac);i++){
		for(k=0;k<chl;k++){
			for(j=0;j<2;j++){
				go=false;
				if(j==priority){
					selectWindow(left);
					nowsl=(i+(sll-starter));
					if(nowsl>0 && nowsl<=slicesl) go=true;
					wid=widl; hei=heil; stx=0; sty=0;
				} else {
					selectWindow(right);
					nowsl=(i+(slr-starter));
					if(nowsl>0 && nowsl<=slicesr) go=true;
					wid=widr; hei=heir;
					//if(bottom) {stx=0; sty=offset;}
					//else {stx=offset; sty=0;}
					stx=x; sty=y;
				}
				if(go){
					Stack.setPosition((k+1), nowsl, 1);
					run("Select All");
					run("Copy");
					selectWindow(left+"-AJCombine");
					Stack.setPosition((k+1), (i+1+begfac), 1);
					makeRectangle(stx,sty,wid,hei);
					run("Paste");
				}
			}
		}
	}

selectWindow(left);
Stack.setSlice(sll);
selectWindow(right);
Stack.setSlice(slr);

selectWindow(left+"-AJCombine");
run("Select None");
for(k=0;k<chl;k++) {Stack.setChannel(k+1); setMinAndMax(mingo[k],maxgo[k]); if(comp) run(colors[k]);}
setBatchMode("exit and display");

selectWindow(left+"-AJCombine");
Stack.setSlice(starter+1+begfac);
//restoreSettings();
setPasteMode("Copy");
}