var Diameter="-";
var AnnoPath=getDirectory("home");
var title="blank";

macro "close cell count [c]" {
//DEPENDENCIES: GET_BASENAME, DEFINE_PATH, CLOSE_ALL_WINDOWS
//mdoc: finalizes cell count by writing the individual counts as well as the overall sum into a comma separated spreadsheet (*.cc.tsv). this spreadsheet is automatically stored in a folder "cellcount" in the annotation folder. if this folder does not exist, it will be created.
	sum=0;
	for (i=0; i<nResults; i++){
		sum=sum+getResult("Number", i);
	}
	if (isOpen("Results")) {
		selectWindow("Results");
	} else {
		roiManager("multi-measure");
	}
	showMessageWithCancel("Closing Cell Counting?","Sum =  "+sum);
	num=nResults;
	setResult("Label", num, "Sum");
	setResult("Number", num, sum);
	updateResults();
	basename=GET_BASENAME(title);
	File.makeDirectory(AnnoPath+"/cellcount");
	print("Saving measurement to "+AnnoPath+"cellcount/"+basename+".cc.tsv");
	saveAs("Measurements", AnnoPath+"cellcount/"+basename+".cc.tsv");
	selectWindow("Results");
	run("Close");
	showMessageWithCancel("auto cloce", "Closing all images now.");
	run("Close All");	
} 
//--------------
macro "configure marks [x]" {
//DEPENDENCIES: CONFIGURE_MARKS
//mdoc: redefines the sixe of the counter mark.
	CONFIGURE_MARKS();
}
//--------------
macro "make marks [z]" {
//DEPENDENCIES: MAKE_MARKS
//mdoc: place cell counter mark and count it.
	title=getTitle();
	if(isKeyDown("alt")){						//delete last mark when alt-key is held
		DELETE_MARK();
	} else if (isKeyDown("space")) {				//assign marks to material when space-key is held
		SUM_MARKS();
	} else {	
		MAKE_MARKS();
	}
	selectWindow(title);
} 
macro "help [h]" {
	showMessage("cellCounter help", "The cellCounter is an interactive macro, which is facilitating the manual counting of cells or other small particles in a volume. \
	For this, the cellCounter separates the navigation and selection between the mouse (navigation in the image only) and \
	the keyboard (click). Since this script was build by a right handed person the key-binding are especially useful for \
	right-handed users but can easily be remapped in the code of the macro.\
	\
	Keyboard functions:\
	z : replaces the left mouse key for setting marks. By this the mouse can be held more still and the work of counting is\
	   	distributed between both hands.\
	alt+z : removes the active mark. This is either the last or the one selected in the ROI-manager.\
	space+z : sums up the current counting process, asks for a name, store sum under given name in the results table and \
	   	potentially triggers the painting of the marks into the image (destructive).\
	x : (re-)configures the size of the mark. \
	c : cleanly closes the process of counting and prepares for the next specimen.\
	h : displays this help.\
	\
	If you data allow, it is recommended to work with this tool on RBG data, because the already counted cells will be \
	more visible.");
}

macro "reinstall [r]"{
	run("Install...", "install="+getDirectory("macros")+"cellCounter.ijm");
}
//--------------

//==================================================================
// CELLCOUNTER FUNCTIONS
//==================================================================
function MAKE_MARKS() {
//DEPENDENCIES: DEFINE_PATH, READ_MEMORY, CONFIGURE_MARKS, WRITE_MEMORY, GET_BASENAME, 
//fdoc: puts circular selections at the current cursor position and prepares counting them using the ROI manager.
	functionID="MAKE_MARKS";
	File.makeDirectory(AnnoPath+"/cellcount");
	setTool(1);
	CONFIGURE_MARKS();
// add mark to image and list
	getCursorLoc(x, y, z, flag);
	makeOval(x-Diameter/2, y-Diameter/2, Diameter, Diameter);
	roiManager("Add");
	setOption("Show All",true);
	makeOval(x-Diameter/2, y-Diameter/2, Diameter, Diameter);
}
function DELETE_MARK() {
	n = roiManager("count");
	roiManager("Select", n-1);
	roiManager("Delete");
	setKeyDown("none");	
}

function SUM_MARKS(){
//	material=READ_MEMORY("CCmaterial", IJmem, IJmemory);
	material="someMaterial";
	sideArray=newArray("", "right", "left");
	Dialog.create("Define neuropil");
//		Dialog.addChoice("Pick it:", neuropils);
	Dialog.addString("Name it:", material);
	Dialog.addChoice("Side:", sideArray, sideArray[0]);
	Dialog.addCheckbox("Save marks as zip", 0);
	Dialog.show();
//		picked=Dialog.getChoice();
	named=Dialog.getString();
	side=Dialog.getChoice();
// picked material name overrules manually entered one.		
//    		if ( picked != "" ) {
//			material=picked;
//			if (side != "") {
//				neuropil=picked+"-"+side;
//			} else{
//				neuropil=picked;
//			}
//		} else {
		material=named;
		if (side != "") {
			neuropil=named+"-"+side;
		} else{
			neuropil=named;
		}
//		}
	zip=Dialog.getCheckbox();
//		WRITE_MEMORY("CCmaterial", material, "CC", IJmem, IJmemory);// write results ot memory
	n = roiManager("count");
	num=nResults;
	setResult("Label", num, neuropil);
	setResult("Number", num, n);
	updateResults();
	basename=GET_BASENAME(title);
	print("saving to "+AnnoPath+"/cellcount/"+basename+".cc.tsv");
	saveAs("Measurements", AnnoPath+"/cellcount/"+basename+".cc.tsv");

Dialog.create(neuropil+"?");					// draw marks into image
Dialog.addMessage("Do you want to paint these positions of "+neuropil+" to the image?");
Dialog.addCheckbox("Save Image", 0);
Dialog.show();
si=Dialog.getCheckbox();
	setBatchMode(true);
	for (j=0; j<n; j++) {
		roiManager("Select", 0);
		ms=getSliceNumber();
		cs=getSliceNumber();
		getSelectionBounds(x, y, width, height);
		if (bitDepth() == 24) {
			setForegroundColor(255,0,0);
		} else {
//			setForegroundColor(0,0,0);
			setForegroundColor(255,255,255);
			fillOval(x, y, width, height);
			setForegroundColor(128,128,128);
		}
		drawOval(x, y, width, height);			// here is the drawing act
		k=round(width/5);
		for (h=k+1; h>0; h--) {
			cs=getSliceNumber();
			if (cs == 1){
				ps = cs;
			} else {
				ps=cs-1;
			}
			h2=height-height/h;
			w2=width-width/h;
			h3=round(h2);
			w3=round(w2);
			setSlice(ps);
			if (bitDepth() == 24) {
				setForegroundColor(255,128,0);
			} else {
//				setForegroundColor(0,0,0);
				setForegroundColor(255,255,255);
				fillOval(x+width/2-w2/2, y+height/2-h2/2, w2, h2);
				setForegroundColor(200,200,200);
			}
			drawOval(x+width/2-w2/2, y+height/2-h2/2, w2, h2); // here is the drawing act
		}
			setSlice(ms);
		for (h=k+1; h>0; h--) {
			cs=getSliceNumber();
			if (cs == nSlices){
				ps = cs;
			} else {
				ps=cs+1;
			}
			h2=height-height/h;
			w2=width-width/h;
			h3=round(h2);
			w3=round(w2);
			setSlice(ps);
			if (bitDepth() == 24) {
				setForegroundColor(0, 0, 255);
			} else {
//				setForegroundColor(0,0,0);
				setForegroundColor(255,255,255);
				fillOval(x+width/2-w2/2, y+height/2-h2/2, w2, h2);
				setForegroundColor(100,100,100);
			}
			drawOval(x+width/2-w2/2, y+height/2-h2/2, w2, h2); // here is the drawing act
		}
		roiManager("Delete");
	}
	setBatchMode(false);
	setKeyDown("none");
	selectWindow(title);
	if (si) {
		print("saving image to "+AnnoPath+"cellcount/"+basename+".cc.tif");
		saveAs("Tiff", AnnoPath+"cellcount/"+basename+".cc.tif");
		rename("title");
	}	
}

//==============
//fdoc: defines the size of the mark of the cell counter.
function CONFIGURE_MARKS() {
//DEPENDENCIES: non
	functionID="CONFIGURE_MARKS";

	setTool(1);
	getSelectionBounds(x, y, width, height);
	if (x+y == 0) {
		exit("Size of cells is not defined. \nHit OK here and then \ndraw ellipse around a sample cell\n or select one from the ROI manager.");
	} else {
		w=width;
		h=height;
		Diameter=(w+h)/2;
	}
	setTool(12);

}
//==============
//fdoc: GET_BASENAME generates the basename from the input it gets passed and writes it to memory, breaks down a standardized file name into its components and writes each of them into the IJ-memory-file. Because this is rather slow GET_FAST_BAESNAME was developed which omits the memory step. 
function GET_BASENAME(input) {
//DEPENDENCIES: DEFINE_PATH, LIST_LOADER, DIRECT_LOADER, STRIP_BASENAME, READ_MEMORY
	functionID="GET_BASENAME";

	if(input == "emptyString") {
		pat=getTitle();
	} else {
		pat=input;
	}
//	basename=exec("sh", "-c", "echo "+pat+"|cut -d \".\" -f 1");
	tmp=split(pat, ".");
	basename=tmp[0];
	basename=split(basename, "\n");
	basename=basename[0];
	return basename;
}