//Prompts user to select folders....
numdir = getDirectory("Select Folder Containing Numerator Image Files");
dendir = getDirectory("Select Folder Containing Denominator Image Files");
outdir =  getDirectory("Select Folder For Output Images");

numlist = getFileList(numdir);
denlist = getFileList(dendir);

if (numlist != denlist) {
	print("Error: Folders must contain the same number of files");
}

// ---------------------------Dialog box 1--------------------------------
Dialog.create("Create Intensity Modulated Display...");

Dialog.addCheckbox("Smooth images prior to division? ", true);
Dialog.show();
smooth = Dialog.getCheckbox();

//Open the files ins the folders....
for (i=0; i<numlist.length; i++) {  //Safe since both folders contain the same number of files

	showProgress((i+1)/numlist.length); //progress bar

	numpath = numdir+numlist[i];
	denpath = dendir+denlist[i];

	open(numpath);
	open(denpath);	

	process();		
	
}

function process () {

//Creates ratio image...
if (smooth == true) {

	selectWindow(numlist[i]);
	run("8-bit");
	run("Gaussian Blur...", "sigma=1");
	selectWindow(denlist[i]);
	run("8-bit");
	run("Gaussian Blur...", "sigma=1");

	imageCalculator("Divide create 32-bit", numlist[i], denlist[i]);

	ratioimg = getTitle();
	
	selectWindow(numlist[i]); //Keep denom image to use for brightness
	close();

}

if (smooth == false) {
 
	selectWindow(numlist[i]);
	run("8-bit");
	selectWindow(denlist[i]);
	run("8-bit");
	
	imageCalculator("Divide create 32-bit", numlist[i], denlist[i]);

	ratioimg = getTitle();

	selectWindow(numlist[i]);  //Keep denom image to use for brightness
	close();
	
}


// ---------------------------Dialog box 2--------------------------------

//Finds the max value in the ratio image...
selectWindow(ratioimg);
run("Enhance Contrast", "saturated=0.1");
getMinAndMax(min, absmax);
//Suggest a max value to display in the ratio image based on its histogram.... 
run("Enhance Contrast", "saturated=1.00");
getMinAndMax(min, sugmax);

Dialog.create("Set Scale...");
Dialog.addSlider("Set maximum displayed value in ratio image: ", 0, absmax, sugmax);
Dialog.addSlider("Set % saturation in denominator image: ", 0.5, 5, 1);
Dialog.show();

usermax = Dialog.getNumber();
usersat = Dialog.getNumber();

selectWindow(ratioimg);
setMinAndMax(0, usermax);  // max as selected by user
run("8-bit");
run("Invert");  //Makes high ratios hot and low ratios cool  (inherently, red hue = 0 -> blue hue = 170)
run("Multiply...", "value=0.666");  // Contstrains hues from 0-170 to match calibration bar (so only red->blue colors are shown)

selectWindow(denlist[i]);
run("Enhance Contrast", "saturated="+usersat);  // as selected by user
run("8-bit");

//----------------------Creates HSB Image -------------------------------------

selectWindow(ratioimg);
getDimensions(ratioimgwidth, ratioimgheight, channels, slices, frames);

//Creates an HSB image... THIS IS THE ONLY WAY TO DO IT!!
newImage(numlist[i]+"IMD", "RGB black", ratioimgwidth, ratioimgheight, 1);
run("HSB Stack");

//Copies the ratio image into the hue channel of the HSB Stack
selectWindow(ratioimg);
run("Select All");
run("Copy");
run("Close");  //closes rationimg
selectWindow(numlist[i]+"IMD");
setSlice(1);
run("Paste");

//Creates the Saturation (constant) image
newImage("Sat", "8-bit white", ratioimgwidth, ratioimgheight, 1);
//Copies the Sat image into the Sat channel of the HSB Stack
selectWindow("Sat");
run("Select All");
run("Copy");
run("Close");  //closes Sat image
selectWindow(numlist[i]+"IMD");
setSlice(2);
run("Paste");


//Copies the denominator image into the brightness channel of the HSB Stack
selectWindow(denlist[i]);
run("Select All");
run("Copy");
run("Close");  //closes deimg
selectWindow(numlist[i]+"IMD");
setSlice(3);
run("Paste");

//Turns the HSB values into an RGB image
run("RGB Color");
run("Select None");

//Saves and closes 
selectWindow(numlist[i]+"IMD");
saveAs("tiff", outdir+numlist[i]+"IMD");
close();


} // EO process

showStatus("IMD Finished!");