/* 
 *	VSI Tiler macro
 *	v1.18.06a
 *	Developed by M Foley, Sydney Microscopy & Microanalysis, University of Sydney
 *  Does not yet handle Z stacks all that well - need to think of a solution...
 *  
 *  
*/

macro "VSI_Tiler..." {
	dir = getDirectory("Where are your VSI files?");
	bool_saveAndClose = 1;	// Autosave TIFF stack
		doCommand("Monitor Memory...");
	print("\\Clear");
	information("Processing started for "+dir);
	fn_processFiles(dir);
	information("Processing complete");
		selectWindow("Memory");
		run("Close");


/*****************************/	
function fn_processFiles(dir){
	list = getFileList(dir);
 	for (i=0; i<list.length; i++){
 		setBatchMode(true);
 		filename = dir+list[i];
 		if(File.isDirectory(filename)){
 			fn_processFiles(filename);
 			}
 		else if(endsWith(filename, ".vsi")){
 			information("Processing "+list[i]);
 			run("Bio-Formats", "open=["+filename+"] color_mode=Default view=Hyperstack stack_order=XYCZT series_12");
 			image = getTitle();
 			/* CREATE OVERVIEW */
 			run("Scale...", "x=- y=- width=512 height=* interpolation=Bilinear average create");
			rename(image+" Overview");
			saveAs("Tiff", dir+File.separator+getTitle()); selectWindow(image+" Overview.tif"); run("Close");
			selectWindow(image); 
 			/* END CREATE OVERVIEW */
 			getDimensions(width, height, null, null, null);
 			fn_processTiles(image, width, height);
			if(bool_saveAndClose){saveAs("Tiff", dir+File.separator+getTitle()); run("Close");}
 				close(image);
 				setBatchMode(false);
 			information("Completed "+list[i]);
			run("Collect Garbage");
 			}
 		}
} // fn_processFiles close	
/*****************************/	

function fn_processTiles(image, width, height){
	tileSize = 2500;
	tileSize = minimum(tileSize, roundTo(maximum(width, height), 3));
stack = 0;
for (x = 0; x<width; x+= tileSize){
	currentTileWidth = width - x;
		if (currentTileWidth > tileSize) 
				currentTileWidth = tileSize;
		for (y = 0; y < height; y += tileSize) { 
				currentTileHeight = height - y;
				
				if (currentTileHeight > tileSize) 
						currentTileHeight = tileSize; 
		selectWindow(image);
		makeRectangle(x, y, currentTileWidth, currentTileHeight);
		run("Duplicate...", "title=Tile duplicate");
		getDimensions(w1,h1,null,null,null);
		if(w1 < tileSize || h1 < tileSize)
{run("Canvas Size...", "width="+tileSize+" height="+tileSize+" position=Top-Left zero");}	// Handling duplicates smaller than tile size

		if (stack ==0) {
			rename("Tiled "+image);
			stack +=1;
			}
			else {run("Concatenate...", "  title=[Tiled "+image+"] open image1=[Tiled "+image+"] image2=Tile image3=[-- None --]");}
		setMetadata("Label", "(x=" + x + ",y=" + y + ")"); 
		}	// y loop close
} // x loop close
}	// fn_processTiles close brace

/*****************************/	

function minimum(a,b){
	result = a;
	if (b<a) result = b;
	return result;
}
function maximum(a,b){
	result = a;
	if (b>a) result = b;
	return result;	
}
function roundTo(value, magnitude){
	result = round(value/pow(10, magnitude))*(pow(10, magnitude));
	return result;
}	
function padZero(a, left){
	while(lengthOf(""+a)<left) a="0"+a;
	return ""+a;
	}

function information(str){
	getDateAndTime(yyy,mm,wk,dd,hour,min,sec,msec);
	message = ""+padZero(hour, 2)+":"+padZero(min,2)+":"+padZero(sec,2)+" - "+str;
	showStatus(str);
	print(message);
	}	
}